[TUTORIAL][Altis Life 4.0+] verschiedene Blaulichter nach Rang

blackfisch

Weil @Saturin78 danach gefragt hat, hab ich mich eben mal ran gesetzt und ein kleines Tutorial für ein THW-Blaulicht (anderes Blaulicht je nach Medic-Level) geschrieben. In abgewandelter Form kann diese Funktion auch für die Polizei hinzugefügt werden.

Script: verschiedene Blaulichter nach Rang
Version: Altis Life 4.4
Schiwerigkeitsgrad: Anfänger (mittel)
Funktionen:
~ verschiedene Blaulichtfarben je nach Medic-Rang

Rechtliche Hinweise (Copyright):
Dieses Script/Tutorial unterliegt keinen sonstigen Copyrightansprüchen meinerseits, da es lediglich auf abgeändertem Code von Tonic, Itsyuka, [GSN] Pager und [GSN] Paronity basiert.

Nun zum eigentlichen Teil dieses Posts...

Anleitung:

Erstelle eine Datei fn_thwLights.sqf im "core\medical" Ordner mit folgendem Inhalt:

C

/*
 File: fn_medicLights.sqf
 Author: [GSN] Pager & [GSN] Paronity
 Website: GSNGaming.com
 Date Created: 2.24.2015
 Date Modified: 2.25.2015 v1.2
*/
private ["_veh","_lightRed","_lightWhite","_lightBlue","_lightsOn","_brightnessHigh","_brightnessLow","_attach","_leftLights","_rightLights","_type","_attenuation"];
_veh = (_this select 0);
_type = typeOf _veh;
_sun = (sunOrMoon < 1);
if (isNil "_veh" || isNull _veh || !(_veh getVariable "lights")) exitWith {};
_lightRed = [247, 160, 10]; // Orange, Farbe in RGB-Werten
_lightBlue = [247, 160, 10]; // siehe oben
_lightWhite = [255, 255, 255];
if (_sun) then
{
 _brightnessLow = 0;
 _brightnessHigh = 10;
 _attenuation = [0.001, 3000, 0, 125000];
} else {
 _brightnessLow = 0;
 _brightnessHigh = 60;
 _attenuation = [0.001, 3000, 0, 400000];
};
_flashes = 2;
_flashOn = 0.1;
_flashOff = 0.001;
_leftLights = [];
_rightLights = [];
_attach =
{
 _isLight = _this select 0;
 _color = _this select 1;
 _position = _this select 2;
 _light = "#lightpoint" createVehicleLocal getPos _veh;
 _light setLightBrightness 0;
 _light setLightAmbient [0,0,0];
 _light setLightAttenuation _attenuation;
 _light setLightIntensity 1000;
 _light setLightFlareSize 1;
 _light setLightFlareMaxDistance 150;
 _light setLightUseFlare true;
 _light setLightDayLight true;
 switch (_color) do
 {
 case "red": { _light setLightColor _lightRed; };
 case "white": { _light setLightColor _lightWhite; };
 case "blue": { _light setLightColor _lightBlue; };
 };
 if (_isLight) then
 {
 _leftLights pushBack [_light, _position];
 } else {
 _rightLights pushBack [_light, _position];
 };
 _light lightAttachObject [_veh, _position];
};
//Fahrzeuge und deren Coordinaten
switch (_type) do
{
 //Fahrzeuge
 case "C_Offroad_01_F":
 {
 [false, "red", [-0.44, 0, 0.525]] call _attach;
 [true, "blue", [0.345, 0, 0.525]] call _attach;
 [false, "red", [0.575, -2.95, -0.77]] call _attach;
 [true, "blue", [-0.645, -2.95, -0.77]] call _attach;
 [false, "white", [0.61, 2.2825, -0.355]] call _attach;
 [true, "white", [-0.695, 2.2825, -0.355]] call _attach;
 };
 case "C_SUV_01_F":
 {
 [false, "red", [-0.39, 2.28, -0.52]] call _attach;
 [true, "blue", [0.38, 2.28, -0.52]] call _attach;
 [false, "red", [-0.86, -2.75, -0.18]] call _attach;
 [true, "blue", [0.86, -2.75, -0.18]] call _attach;
 [false, "white", [0.8, 1.95, -0.48]] call _attach;
 [true, "white", [-0.8, 1.95, -0.48]] call _attach;
 };
 case "C_Hatchback_01_F":
 {
 [false, "red", [-0.03, -0, 0.2]] call _attach;
 [true, "blue", [-0.03, -0, 0.2]] call _attach;
 [false, "red", [-0.8, -2.25, -0.3]] call _attach;
 [true, "blue", [0.78, -2.25, -0.3]] call _attach;
 [false, "white", [0.75, 1.615, -0.52]] call _attach;
 [true, "white", [-0.8, 1.615, -0.525]] call _attach;
 };
 case "C_Hatchback_01_sport_F":
 {
 [false, "red", [-0.03, -0, 0.2]] call _attach;
 [true, "blue", [-0.03, -0, 0.2]] call _attach;
 [false, "red", [-0.8, -2.25, -0.3]] call _attach;
 [true, "blue", [0.78, -2.25, -0.3]] call _attach;
 [false, "white", [0.75, 1.615, -0.52]] call _attach;
 [true, "white", [-0.8, 1.615, -0.525]] call _attach;
 };
 case "B_MRAP_01_F":
 {
 [false, "red", [-0.85, -0.9, 0.6]] call _attach;
 [true, "blue", [0.85, -0.9, 0.6]] call _attach;
 [true, "red", [-0.93, -2.8, 0.6]] call _attach;
 [false, "blue", [0.93, -2.8, 0.6]] call _attach;
 [true, "white", [-0.85, 1.475, -0.75]] call _attach;
 [false, "white", [0.85, 1.475, -0.75]] call _attach;
 };
 case "B_MRAP_01_hmg_F":
 {
 [false, "red", [-0.85, -0.9, 0.5]] call _attach;
 [true, "blue", [0.85, -0.9, 0.5]] call _attach;
 [true, "red", [-0.93, -2.8, 0.5]] call _attach;
 [false, "blue", [0.93, -2.8, 0.5]] call _attach;
 [true, "white", [-0.85, 1.475, -0.85]] call _attach;
 [false, "white", [0.85, 1.475, -0.85]] call _attach;
 };
 case "I_MRAP_03_F":
 {
 [false, "red", [-0.37, 0.0, 0.50]] call _attach;
 [true, "blue", [-0.37, 0.0, 0.50]] call _attach;
 [true, "red", [0.37, 0.0, 0.50]] call _attach;
 [false, "blue", [0.37, 0.0, 0.50]] call _attach;
 };
 case "C_Van_01_box_F": 
 { 
 [false, "red", [-0.4, 0.00, 1.300]] call _attach;
 [true, "blue", [0.4, 0.00, 1.300]] call _attach;
 [false, "red", [-0.87, 2.2, -0.75]] call _attach;
 [true, "blue", [0.87, 2.2, -0.75]] call _attach;
 [false, "red", [-0.725, -3.45, 1.300]] call _attach;
 [true, "blue", [0.725, -3.45, 1.300]] call _attach;
 [false, "white", [-0.80, 1.85, -0.4]] call _attach;
 [true, "white", [0.80, 1.85, -0.4]] call _attach;
 };
 case "B_Truck_01_transport_F":
 {
 [false, "red", [-0.94, 4.84, 0.45]] call _attach;
 [true, "blue", [0.94, 4.84, 0.45]] call _attach;
 [false, "red", [-0.33, -4.43, -1]] call _attach;
 [true, "blue", [0.33, -4.43, -1]] call _attach;
 [false, "white", [-0.94, 5.1, -0.5]] call _attach;
 [true, "white", [0.94, 5.1, -0.5]] call _attach;
 };
 case "I_Truck_02_box_F":
 {
 [false, "red", [-0.8, -3.5, 1]] call _attach;
 [true, "blue", [0.8, -3.5, 1]] call _attach;
 [false, "red", [-0.87, 3.25, 0.55]] call _attach;
 [true, "blue", [0.87, 3.25, 0.55]] call _attach;
 [false, "red", [-0.84, -3.4, -1.3]] call _attach;
 [true, "blue", [0.84, -3.4, -1.3]] call _attach;
 [false, "white", [-0.85, 3.9, -0.85]] call _attach;
 [true, "white", [0.85, 3.9, -0.85]] call _attach;
 };
 //Helikopter
 case "B_Heli_Light_01_F":
 { 
 [false, "red", [-0.37, 0.0, 0.56]] call _attach;
 [true, "blue", [0.37, 0.0, 0.56]] call _attach;
 [false, "red", [-0.37, 0.0, 0.56]] call _attach;
 [true, "blue", [0.37, 0.0, 0.56]] call _attach; 
 };
 case "C_Heli_light_01_vrana_F":
 { 
 [false, "red", [-0.37, 0.0, 0.56]] call _attach;
 [true, "blue", [0.37, 0.0, 0.56]] call _attach;
 [false, "red", [-0.37, 0.0, 0.56]] call _attach;
 [true, "blue", [0.37, 0.0, 0.56]] call _attach; 
 };
 case "B_Heli_Transport_01_F":
 { 
 [false, "red", [-0.5, 0.0, 0.96]] call _attach;
 [true, "blue", [0.5, 0.0, 0.96]] call _attach;
 [false, "red", [-0.5, 0.0, 0.96]] call _attach;
 [true, "blue", [0.5, 0.0, 0.96]] call _attach; 
 };
 case "I_Heli_light_03_unarmed_F":
 { 
 [false, "red", [-0.37, 0.0, 0.56]] call _attach;
 [true, "blue", [0.37, 0.0, 0.56]] call _attach;
 [false, "red", [-0.37, 0.0, 0.56]] call _attach;
 [true, "blue", [0.37, 0.0, 0.56]] call _attach; 
 };
};
_lightsOn = true;
while {(alive _veh)} do
{
 if (!(_veh getVariable "lights")) exitWith {};
 if (_lightsOn) then
 {
 for [{_i=0}, {_i<_flashes}, {_i=_i+1}] do
 {
 { (_x select 0) setLightBrightness _brightnessHigh; } forEach _leftLights;
 uiSleep _flashOn;
 { (_x select 0) setLightBrightness _brightnessLow; } forEach _leftLights;
 uiSleep _flashOff;
 };
 { (_x select 0) setLightBrightness 0; } forEach _leftLights;
 for [{_i=0}, {_i<_flashes}, {_i=_i+1}] do
 {
 { (_x select 0) setLightBrightness _brightnessHigh; } forEach _rightLights;
 uiSleep _flashOn;
 { (_x select 0) setLightBrightness _brightnessLow; } forEach _rightLights;
 uiSleep _flashOff;
 };
 { (_x select 0) setLightBrightness 0; } forEach _rightLights;
 };
};
{ deleteVehicle (_x select 0) } foreach _leftLights;
{ deleteVehicle (_x select 0) } foreach _rightLights;
_leftLights = [];
_rightLights = [];

Alles anzeigen

Ersetze in der fn_medicSirenLights.sqf die Zeile [_vehicle,0.22] remoteExec ["life_fnc_medicLights",RCLIENT]; durch:

C

if ((call life_mediclevel) < 3) exitWith { [_vehicle,0.22] remoteExec ["life_fnc_thwLights",RCLIENT]; };
if ((call life_mediclevel) > 3) exitWith { [_vehicle,0.22] remoteExec ["life_fnc_medicLights",RCLIENT];};

Öffne deine Functions.hpp und füge unter "class Medical_System" folgendes ein:
C
```
class thwLights {};
```
Öffne deine CfgRemoteExec.hpp und füge unter "class Functions" folgendes ein:
C
```
F(life_fnc_medLights,CLIENT)
F(life_fnc_thwLights,CLIENT)
```

P.S.: Wenn ihr die Farben ändern wollt, einfach die RGB_Werte von "_lightRed" und "_lightBlue" ändern. Die RGB-Werte könnt ihr z.B. hier [KLICK MICH] herausfinden. Wichtig sind die letzten drei Zahlen rechts, diese in der Reihenfolge oben einfügen.

Fertig!
Das war's schon!

Ich wünsche euch Viel Spaß mit dem Tutorial

Saturin78

Super, besten Dank.

Saturin78

Besten Dank dass du dir so viel Mühe gibst.

ich habe aber in der mission keine CfgRemoteExec.hpp. Habe mir dann eine eingefügt aus der NN Mission und die Veränderung gemacht. Allerdings bringt er mir ne Fehlermeldung.

Muss die cfgremoteexec.hpp noch irgendwo definiert werden?

Die die ich nun drin habe sieht so aus:

Bash: CfgRemoteExec.hpp

class CfgRemoteExec
{
	class Functions
	{
		F(life_fnc_medLights,CLIENT)
		F(life_fnc_thwLights,CLIENT)
		mode = 1;
		jip = 0;
		class fnc_AdminReq { allowedTargets=2; };
		class EPOCH_server_save_vehicles { allowedTargets=2; };
	};
	class Commands
	{
		mode=0;
		jip=0;
	};
};

Alles anzeigen

meine medicSirenenLights sieht so aus. Das ausgeklammerte ist das originale.

Bash: fn_medic_SirenLights.sqf

/*
	File: fn_sirenLights.sqf
	Author: Bryan "Tonic" Boardwine

	Description:
	Lets play a game! Can you guess what it does? I have faith in you, if you can't
	then you have failed me and therefor I lose all faith in humanity.. No pressure.
*/
private["_vehicle"];
_vehicle = [_this,0,ObjNull,[ObjNull]] call BIS_fnc_param;
if(isNull _vehicle) exitWith {}; //Bad entry!
if(!(typeOf _vehicle in ["B_Truck_01_transport_F","I_Truck_02_box_F","C_Hatchback_01_F","C_Hatchback_01_sport_F","B_Heli_Light_01_F","B_Heli_Transport_01_F","I_Heli_light_03_unarmed_F","I_MRAP_03_F","B_MRAP_01_hmg_F","C_Van_01_box_F","C_Offroad_01_F","B_MRAP_01_F","C_SUV_01_F"])) exitWith {}; //Last chance check to prevent something from defying humanity and creating a monster.




_trueorfalse = _vehicle getVariable["lights",FALSE];




if(_trueorfalse) then {
	_vehicle setVariable["lights",FALSE,TRUE];
} else {
	_vehicle setVariable["lights",TRUE,TRUE];
	if ((call life_mediclevel) < 3) exitWith { [_vehicle,0.22] remoteExec ["life_fnc_thwLights",RCLIENT]; };
	if ((call life_mediclevel) > 3) exitWith { [_vehicle,0.22] remoteExec ["life_fnc_medicLights",RCLIENT];};
	//[[_vehicle,0.22],"life_fnc_medicLights",true,false] call life_fnc_MP; <-- Das war vorher drin!
};

Alles anzeigen

blackfisch

Hey, falls du mit 3.1.4.8 arbeitest funktioniert das wahrscheinlich NICHT, ich bin von der 4.4 ausgegangen, weil diese die aktuellste ist und die einzige, die 3D-Missionfiles akzeptiert (wird mit 3.1.4.8 lustig nach APEX ohne 2D Editor ^^)
Wenn du magst kann ich heute Abend nochmal für 3.1.4.8 einen Blick drauf werfen.

Saturin78

Ich hab die 4.0.

Habe es so abgeändert. Sieht auf den ersten Blick so aus dass es klappt. Kann nur nicht sagen ob es nun wenn einer mit medic_lvl höher 3 und einer mit kleiner 3 drauf ist auch für jeden das richitge Licht an ist. War beim ersten Versuch so dass der höher lvl 3 die Lichter rot/blau sah und der niedriger lvl 3 die gelb gesehen hatte. Werd ich testen sobald wieder jemand vom Team da ist :-9

Bash: fn_medicSirenLights.sqf

/*
	File: fn_sirenLights.sqf
	Author: Bryan "Tonic" Boardwine

	Description:
	Lets play a game! Can you guess what it does? I have faith in you, if you can't
	then you have failed me and therefor I lose all faith in humanity.. No pressure.
*/
private["_vehicle"];
_vehicle = [_this,0,ObjNull,[ObjNull]] call BIS_fnc_param;
if(isNull _vehicle) exitWith {}; //Bad entry!
if(!(typeOf _vehicle in ["B_Truck_01_transport_F","I_Truck_02_box_F","C_Hatchback_01_F","C_Hatchback_01_sport_F","B_Heli_Light_01_F","B_Heli_Transport_01_F","I_Heli_light_03_unarmed_F","I_MRAP_03_F","B_MRAP_01_hmg_F","C_Van_01_box_F","C_Offroad_01_F","B_MRAP_01_F","C_SUV_01_F"])) exitWith {}; //Last chance check to prevent something from defying humanity and creating a monster.




_trueorfalse = _vehicle getVariable["lights",FALSE];




if(_trueorfalse) then {
	_vehicle setVariable["lights",FALSE,TRUE];
} else {
	_vehicle setVariable["lights",TRUE,TRUE];
	//if ((call life_mediclevel) < 3) exitWith { [_vehicle,0.22] remoteExec ["life_fnc_thwLights",RCLIENT]; };
	//if ((call life_mediclevel) > 3) exitWith { [_vehicle,0.22] remoteExec ["life_fnc_medicLights",RCLIENT];};
	//[[_vehicle,0.22],"life_fnc_medicLights",true,false] call life_fnc_MP;
	if ((call life_mediclevel) < 3) exitWith {[[_vehicle,0.22],"life_fnc_thwLights",true,false] call life_fnc_MP;};
	if ((call life_mediclevel) <= 3) exitWith {[[_vehicle,0.22],"life_fnc_medicLights",true,false] call life_fnc_MP;};
};

Alles anzeigen

blackfisch

C

if ((call life_mediclevel) < 3) exitWith {[[_vehicle,0.22],"life_fnc_thwLights",true,false] call life_fnc_MP;};
if ((call life_mediclevel) <= 3) exitWith {[[_vehicle,0.22],"life_fnc_medicLights",true,false] call life_fnc_MP;};

Einmal kleiner 3 und einmal kleiner/gleich drei? sicher, dass das so soll?

Saturin78

ups, Zeichen vertauscht Danke.

blackfisch

Gerne doch Man hilft, wo man kann. #A3besteCommunity

[TUTORIAL][Altis Life 4.0+] verschiedene Blaulichter nach Rang

Tags

Benutzer online in diesem Thema