Blaulichter & Medic Heli Shop Problem!?

John_Parker

Hallo liebe NN Community,

Ich habe folgendes Problem mit meinem Blaulichtern (Shift+L).

Wie z.B bei den Medics gehen die Blaulichter überhaupt nicht & bei den Cops nur bei paar Fahrzeugen.
@nox hatte mir zwar gesagt das der Fehler irgend wo in der Life_Server/Functions/Systems/fn_spawnVehicle.sqf liegt aber ich kann hier nichts finden.
Und bei dem Flugzeug Shop von den Medics werden bei mir auch keine Helikopter bzw überhaupt irgend welche flugzeuge/helikopter zum kaufen angezeigt, obwohl ich sie eingetragen habe.

Könnte mir da jemand weiterhelfen ?

Hier der Code von der fn_spawnVehicle.sqf wo ich denke das der fehler liegt aber kann nichts finden bzw weiß nicht woran es liegen könnte:

Code

//Sets of animations
    if(EQUAL(SEL(_vInfo,1),"civ") && EQUAL(SEL(_vInfo,2),"B_Heli_Light_01_F") && !(EQUAL(SEL(_vInfo,8),13))) then {
    [[_vehicle,"civ_littlebird",true],"life_fnc_vehicleAnimate",_unit,false] call life_fnc_MP;
    };
    if(EQUAL(SEL(_vInfo,1),"cop") && (SEL(_vInfo,2)) in ["C_Offroad_01_F","B_MRAP_01_F","C_SUV_01_F","C_Hatchback_01_sport_F"]) then {
    [[_vehicle,"cop_offroad",true],"life_fnc_vehicleAnimate",_unit,false] call life_fnc_MP;
    };
    if(EQUAL(SEL(_vInfo,1),"med") && (SEL(_vInfo,2)) in ["C_Offroad_01_F","C_Van_01_box_F","C_SUV_01_F","C_Hatchback_01_sport_F","B_MRAP_01_F"]) then {
    [[_vehicle,"med_offroad",true],"life_fnc_vehicleAnimate",_unit,false] call life_fnc_MP;
    };
    [[1,"Your vehicle is ready!"],"life_fnc_broadcast",_unit,false,true] call life_fnc_MP;
    serv_sv_use deleteAt _servIndex;

Alles anzeigen

SBuserhy

wenn du nur einen kleinen Auszug aus der Datei anhängst, können wir nur raten ... und auf raten hat keiner bock

also entweder du postest deine kompletten Dateien die du geändert hast oder das Thema ist nur für Illuminatis geeignet.

John_Parker

Zitat von SBuserhy

wenn du nur einen kleinen Auszug aus der Datei anhängst, können wir nur raten ... und auf raten hat keiner bock

also entweder du postest deine kompletten Dateien die du geändert hast oder das Thema ist nur für Illuminatis geeignet.

Hehe
Coole Antwort muss ich schon sagen.

Jop Code kommt sofort bitteschööön:

Code

#include "\life_server\script_macros.hpp"
/*
	File: fn_spawnVehicle.sqf
	Author: Bryan "Tonic" Boardwine




	Description:
	Sends the query request to the database, if an array is returned then it creates
	the vehicle if it's not in use or dead.
*/
private["_vid","_sp","_pid","_query","_sql","_vehicle","_nearVehicles","_name","_side","_tickTime","_dir","_servIndex"];
_vid = [_this,0,-1,[0]] call BIS_fnc_param;
_pid = [_this,1,"",[""]] call BIS_fnc_param;
_sp = [_this,2,[],[[],""]] call BIS_fnc_param;
_unit = [_this,3,ObjNull,[ObjNull]] call BIS_fnc_param;
_price = [_this,4,0,[0]] call BIS_fnc_param;
_dir = [_this,5,0,[0]] call BIS_fnc_param;
_unit_return = _unit;
_name = name _unit;
_side = side _unit;
_unit = owner _unit;




if(EQUAL(_vid,-1) OR EQUAL(_pid,"")) exitWith {};
if(_vid in serv_sv_use) exitWith {};
serv_sv_use pushBack _vid;
_servIndex = serv_sv_use find _vid;




_query = format["vehicleInfo:%1:%2",_vid,_pid];







_tickTime = diag_tickTime;
_queryResult = [_query,2] call DB_fnc_asyncCall;




if((EQUAL(EXTDB_SETTINGS("MySQL_Query"),1))) then {
	["diag_log",[
		"------------- Vehicle Query Request -------------",
		format["QUERY: %1",_query],
		format["Time to complete: %1 (in seconds)",(diag_tickTime - _tickTime)],
		format["Result: %1",_queryResult],
		"-------------------------------------------------"
	]] call TON_fnc_logIt;
};




if(EQUAL(typeName _queryResult,typeName "")) exitWith {};




_vInfo = _queryResult;
if(isNil "_vInfo") exitWith {serv_sv_use deleteAt _servIndex;};
if(EQUAL(count _vInfo,0)) exitWith {serv_sv_use deleteAt _servIndex;};




if(EQUAL(SEL(_vInfo,5),0)) exitWith {
	serv_sv_use deleteAt _servIndex;
	[[1,format[(localize "STR_Garage_SQLError_Destroyed"),_vInfo select 2]],"life_fnc_broadcast",_unit,false,true] call life_fnc_MP;
};




if(EQUAL(SEL(_vInfo,6),1)) exitWith {
	serv_sv_use deleteAt _servIndex;
	[[1,format[(localize "STR_Garage_SQLError_Active"),_vInfo select 2]],"life_fnc_broadcast",_unit,false,true] call life_fnc_MP;
};




if!(EQUAL(typeName _sp,typeName "")) then {
	_nearVehicles = nearestObjects[_sp,["Car","Air","Ship"],10];
} else {
	_nearVehicles = [];
};




if(count _nearVehicles > 0) exitWith {
	serv_sv_use deleteAt _servIndex;
	[[_price,_unit_return],"life_fnc_garageRefund",_unit,false] call life_fnc_MP;
	[[1,(localize "STR_Garage_SpawnPointError")],"life_fnc_broadcast",_unit,false,true] call life_fnc_MP;
};




_query = format["vehicleUpdateActive:1:%1:%2",_pid,_vid];







[_query,false] spawn DB_fnc_asyncCall;
if(typeName _sp == "STRING") then {
	_vehicle = createVehicle[(_vInfo select 2),[0,0,999],[],0,"NONE"];
	waitUntil {!isNil "_vehicle" && {!isNull _vehicle}};
	_vehicle allowDamage false;
	_hs = nearestObjects[getMarkerPos _sp,["Land_Hospital_side2_F"],50] select 0;
	_vehicle setPosATL (_hs modelToWorld [-0.4,-4,12.65]);
	sleep 0.6;
} else {
	_vehicle = createVehicle [(_vInfo select 2),_sp,[],0,"NONE"];
	waitUntil {!isNil "_vehicle" && {!isNull _vehicle}};
	_vehicle allowDamage false;
	_vehicle setPos _sp;
	_vehicle setVectorUp (surfaceNormal _sp);
	_vehicle setDir _dir;
};
_vehicle allowDamage true;
//Send keys over the network.
[[_vehicle],"life_fnc_addVehicle2Chain",_unit,false] call life_fnc_MP;
[_pid,_side,_vehicle,1] call TON_fnc_keyManagement;
_vehicle lock 2;
//Reskin the vehicle
[[_vehicle,_vInfo select 8],"life_fnc_colorVehicle",nil,false] call life_fnc_MP;
_vehicle setVariable["vehicle_info_owners",[[_pid,_name]],true];
_vehicle setVariable["dbInfo",[(_vInfo select 4),_vInfo select 7]];
//_vehicle addEventHandler["Killed","_this spawn TON_fnc_vehicleDead"]; //Obsolete function?
[_vehicle] call life_fnc_clearVehicleAmmo;




//Sets of animations




if(EQUAL(SEL(_vInfo,1),"civ") && EQUAL(SEL(_vInfo,2),"B_Heli_Light_01_F") && !(EQUAL(SEL(_vInfo,8),13))) then {
	[[_vehicle,"civ_littlebird",true],"life_fnc_vehicleAnimate",_unit,false] call life_fnc_MP;
};




if(EQUAL(SEL(_vInfo,1),"cop") && (SEL(_vInfo,2)) in ["C_Offroad_01_F","B_MRAP_01_F","C_SUV_01_F","C_Hatchback_01_sport_F"]) then {
	[[_vehicle,"cop_offroad",true],"life_fnc_vehicleAnimate",_unit,false] call life_fnc_MP;
};




if(EQUAL(SEL(_vInfo,1),"med") && (SEL(_vInfo,2)) in ["C_Offroad_01_F","C_Van_01_box_F","C_SUV_01_F","C_Hatchback_01_sport_F","B_MRAP_01_F"]) then {
	[[_vehicle,"med_offroad",true],"life_fnc_vehicleAnimate",_unit,false] call life_fnc_MP;
};
[[1,"Your vehicle is ready!"],"life_fnc_broadcast",_unit,false,true] call life_fnc_MP;
serv_sv_use deleteAt _servIndex;

Alles anzeigen

Tawil

Es ist in dem Dateianhang sehr unübersichtlich.
Lad die Datei einfach mal hoch.

Das ich sie per Notepad anschauen kann.

SBuserhy

sieht ok aus. jetzt noch die folgenden Dateien:

core/cop/fn_copLights.sqf
core/cop/fn_sirenLights.sqf

core/medical/fn_medicLights.sqf
core/medical/fn_medicSirenLights.sqf

core/function/fn_keyhandler.sqf

John_Parker

fn_coplights.sqf:

Code

/*
    File: fn_medicLights.sqf
    Author: [GSN] Pager & [GSN] Paronity
    Website: GSNGaming.com
    Date Created: 2.24.2015
    Date Modified: 2.25.2015 v1.2
*/




private ["_veh","_lightRed","_lightWhite","_lightBlue","_lightsOn","_brightnessHigh","_brightnessLow","_attach","_leftLights","_rightLights","_type","_attenuation"];




_veh = (_this select 0);
_type = typeOf _veh;
_sun = (sunOrMoon < 1);




if (isNil "_veh" || isNull _veh || !(_veh getVariable "lights")) exitWith {};




_lightRed = [255, 0, 0];
_lightWhite = [255, 255, 255];
_lightBlue = [0, 0, 255];




if (_sun) then
{
    _brightnessLow = 0;
    _brightnessHigh = 10;
    _attenuation = [0.001, 3000, 0, 125000];
} else {
    _brightnessLow = 0;
    _brightnessHigh = 60;
    _attenuation = [0.001, 3000, 0, 400000];
};




_flashes = 2;
_flashOn = 0.1;
_flashOff = 0.001;




_leftLights = [];
_rightLights = [];




_attach =
{
    _isLight = _this select 0;
    _color = _this select 1;
    _position = _this select 2;
    _light = "#lightpoint" createVehicleLocal getPos _veh;
    _light setLightBrightness 0;
    _light setLightAmbient [0,0,0];
    _light setLightAttenuation _attenuation;
    _light setLightIntensity 1000;
    _light setLightFlareSize 1;
    _light setLightFlareMaxDistance 150;
    _light setLightUseFlare true;
    _light setLightDayLight true;




    switch (_color) do
    {
        case "red": { _light setLightColor _lightRed; };
        case "white": { _light setLightColor _lightWhite; };
        case "blue": { _light setLightColor _lightBlue; };
    };




    if (_isLight) then
    {
        _leftLights pushBack [_light, _position];
    } else {
        _rightLights pushBack [_light, _position];
    };




    _light lightAttachObject [_veh, _position];
};




switch (_type) do
{
    case "C_Offroad_01_F":
    {
        [false, "red", [-0.44, 0, 0.525]] call _attach;
        [true, "blue", [0.345, 0, 0.525]] call _attach;
        [false, "red", [0.575, -2.95, -0.77]] call _attach;
        [true, "blue", [-0.645, -2.95, -0.77]] call _attach;
        [false, "white", [0.61, 2.2825, -0.355]] call _attach;
        [true, "white", [-0.695, 2.2825, -0.355]] call _attach;
    };




    case "C_SUV_01_F":
    {
        [false, "red", [-0.39, 2.28, -0.52]] call _attach;
        [true, "blue", [0.38, 2.28, -0.52]] call _attach;
        [false, "red", [-0.86, -2.75, -0.18]] call _attach;
        [true, "blue", [0.86, -2.75, -0.18]] call _attach;
        [false, "white", [0.8, 1.95, -0.48]] call _attach;
        [true, "white", [-0.8, 1.95, -0.48]] call _attach;




    };




    case "C_Hatchback_01_sport_F":
    {
        [false, "red", [-0.03, -0, 0.2]] call _attach;
        [true, "blue", [-0.03, -0, 0.2]] call _attach;
        [false, "red", [-0.8, -2.25, -0.3]] call _attach;
        [true, "blue", [0.78, -2.25, -0.3]] call _attach;
        [false, "white", [0.75, 1.615, -0.52]] call _attach;
        [true, "white", [-0.8, 1.615, -0.525]] call _attach;
    };




    case "B_MRAP_01_F":
    {
        [false, "red", [-0.85, -0.9, 0.6]] call _attach;
        [true, "blue", [0.85, -0.9, 0.6]] call _attach;
        [true, "red", [-0.93, -2.8, 0.6]] call _attach;
        [false, "blue", [0.93, -2.8, 0.6]] call _attach;
        [true, "white", [-0.85, 1.475, -0.75]] call _attach;
        [false, "white", [0.85, 1.475, -0.75]] call _attach;
    };
	case "I_MRAP_03_F":
	{
		[false, "red", [-0.37, 0.0, 0.50]] call _attach;
		[true, "blue", [-0.37, 0.0, 0.50]] call _attach;
		[true, "red", [0.37, 0.0, 0.50]] call _attach;
		[false, "blue", [0.37, 0.0, 0.50]] call _attach;
	};	
};




_lightsOn = true;
while {(alive _veh)} do
{
    if (!(_veh getVariable "lights")) exitWith {};
    if (_lightsOn) then
    {
        for [{_i=0}, {_i<_flashes}, {_i=_i+1}] do
        {
            { (_x select 0) setLightBrightness _brightnessHigh; } forEach _leftLights;
            uiSleep _flashOn;
            { (_x select 0) setLightBrightness _brightnessLow; } forEach _leftLights;
            uiSleep _flashOff;
        };
        { (_x select 0) setLightBrightness 0; } forEach _leftLights;




        for [{_i=0}, {_i<_flashes}, {_i=_i+1}] do
        {
            { (_x select 0) setLightBrightness _brightnessHigh; } forEach _rightLights;
            uiSleep _flashOn;
            { (_x select 0) setLightBrightness _brightnessLow; } forEach _rightLights;
            uiSleep _flashOff;
        };
        { (_x select 0) setLightBrightness 0; } forEach _rightLights;
    };
};




{ deleteVehicle (_x select 0) } foreach _leftLights;
{ deleteVehicle (_x select 0) } foreach _rightLights;




_leftLights = [];
_rightLights = [];

Alles anzeigen

fn_sirenLights.sqf:

Code

/*
	File: fn_sirenLights.sqf
	Author: Bryan "Tonic" Boardwine
	Description:
	Lets play a game! Can you guess what it does? I have faith in you, if you can't
	then you have failed me and therefor I lose all faith in humanity.. No pressure.
*/
private["_vehicle"];
_vehicle = [_this,0,ObjNull,[ObjNull]] call BIS_fnc_param;
if(isNull _vehicle) exitWith {}; //Bad entry!
if(!(typeOf _vehicle in ["C_Offroad_01_F","B_MRAP_01_F","C_SUV_01_F","I_Heli_light_03_F","B_Heli_Light_01_F","C_Hatchback_01_sport_F","I_MRAP_03_F","O_MRAP_02_F","O_MRAP_02_hmg_F","B_MRAP_01_hmg_F","I_MRAP_03_hmg_F","C_Van_01_box_F"])) exitWith {}; //Last chance check to prevent something from defying humanity and creating a monster.




_trueorfalse = _vehicle getVariable["lights",FALSE];




if(_trueorfalse) then {
	_vehicle setVariable["lights",FALSE,TRUE];
} else {
	_vehicle setVariable["lights",TRUE,TRUE];
	[[_vehicle,0.22],"life_fnc_copLights",true,false] call life_fnc_MP;
};

Alles anzeigen

fn_medicLights.sqf:

Code

/*
    File: fn_medicLights.sqf
    Author: [GSN] Pager & [GSN] Paronity
    Website: GSNGaming.com
    Date Created: 2.24.2015
    Date Modified: 2.25.2015 v1.2
*/




private ["_veh","_lightRed","_lightWhite","_lightYellow","_lightsOn","_brightnessHigh","_brightnessLow","_attach","_leftLights","_rightLights","_type","_attenuation"];




_veh = (_this select 0);
_type = typeOf _veh;
_sun = (sunOrMoon < 1);




if (isNil "_veh" || isNull _veh || !(_veh getVariable "lights")) exitWith {};




_lightRed = [255, 0, 0];
_lightWhite = [255, 255, 255];
_lightYellow = [255, 255, 0];




if (_sun) then
{
    _brightnessLow = 0;
    _brightnessHigh = 10;
    _attenuation = [0.001, 3000, 0, 125000];
} else {
    _brightnessLow = 0;
    _brightnessHigh = 60;
    _attenuation = [0.001, 3000, 0, 400000];
};




_flashes = 2;
_flashOn = 0.1;
_flashOff = 0.001;




_leftLights = [];
_rightLights = [];




_attach =
{
    _isLight = _this select 0;
    _color = _this select 1;
    _position = _this select 2;
    _light = "#lightpoint" createVehicleLocal getPos _veh;
    _light setLightBrightness 0;
    _light setLightAmbient [0,0,0];
    _light setLightAttenuation _attenuation;
    _light setLightIntensity 1000;
    _light setLightFlareSize 1;
    _light setLightFlareMaxDistance 150;
    _light setLightUseFlare true;
    _light setLightDayLight true;




    switch (_color) do
    {
        case "red": { _light setLightColor _lightRed; };
        case "white": { _light setLightColor _lightWhite; };
        case "yellow": { _light setLightColor _lightYellow; };
    };




    if (_isLight) then
    {
        _leftLights pushBack [_light, _position];
    } else {
        _rightLights pushBack [_light, _position];
    };




    _light lightAttachObject [_veh, _position];
};




switch (_type) do
{
    case "C_Offroad_01_F":
    {
        [false, "red", [-0.44, 0, 0.525]] call _attach;
        [true, "yellow", [0.345, 0, 0.525]] call _attach;
        [false, "red", [0.575, -2.95, -0.77]] call _attach;
        [true, "yellow", [-0.645, -2.95, -0.77]] call _attach;
        [false, "white", [0.61, 2.2825, -0.355]] call _attach;
        [true, "white", [-0.695, 2.2825, -0.355]] call _attach;
    };




    case "C_SUV_01_F":
    {
        [false, "red", [-0.39, 2.28, -0.52]] call _attach;
        [true, "yellow", [0.38, 2.28, -0.52]] call _attach;
        [false, "red", [-0.86, -2.75, -0.18]] call _attach;
        [true, "yellow", [0.86, -2.75, -0.18]] call _attach;
        [false, "white", [0.8, 1.95, -0.48]] call _attach;
        [true, "white", [-0.8, 1.95, -0.48]] call _attach;




    };




    case "C_Hatchback_01_sport_F":
    {
        [false, "red", [-0.03, -0, 0.2]] call _attach;
        [true, "yellow", [-0.03, -0, 0.2]] call _attach;
        [false, "red", [-0.8, -2.25, -0.3]] call _attach;
        [true, "yellow", [0.78, -2.25, -0.3]] call _attach;
        [false, "white", [0.75, 1.615, -0.52]] call _attach;
        [true, "white", [-0.8, 1.615, -0.525]] call _attach;
    };




    case "I_MRAP_03_F":
    {
        [false, "red", [-0.87, 2.2, -0.75]] call _attach;
        [true, "yellow", [0.87, 2.2, -0.75]] call _attach;
        [false, "red", [-0.725, -3.15, 0.025]] call _attach;
        [true, "yellow", [0.725, -3.25, 0.025]] call _attach;
        [false, "white", [1.05, 2.25, -0.3]] call _attach;
        [true, "white", [-1.05, 2.25, -0.3]] call _attach;
    };
	case "C_Van_01_box_F":
    {
        [false, "red", [-0.87, 2.2, -0.75]] call _attach;
        [true, "yellow", [0.87, 2.2, -0.75]] call _attach;
        [false, "red", [-0.725, -3.15, 0.025]] call _attach;
        [true, "yellow", [0.725, -3.25, 0.025]] call _attach;
        [false, "white", [1.05, 2.25, -0.3]] call _attach;
        [true, "white", [-1.05, 2.25, -0.3]] call _attach;
    };
};




_lightsOn = true;
while {(alive _veh)} do
{
    if (!(_veh getVariable "lights")) exitWith {};
    if (_lightsOn) then
    {
        for [{_i=0}, {_i<_flashes}, {_i=_i+1}] do
        {
            { (_x select 0) setLightBrightness _brightnessHigh; } forEach _leftLights;
            uiSleep _flashOn;
            { (_x select 0) setLightBrightness _brightnessLow; } forEach _leftLights;
            uiSleep _flashOff;
        };
        { (_x select 0) setLightBrightness 0; } forEach _leftLights;




        for [{_i=0}, {_i<_flashes}, {_i=_i+1}] do
        {
            { (_x select 0) setLightBrightness _brightnessHigh; } forEach _rightLights;
            uiSleep _flashOn;
            { (_x select 0) setLightBrightness _brightnessLow; } forEach _rightLights;
            uiSleep _flashOff;
        };
        { (_x select 0) setLightBrightness 0; } forEach _rightLights;
    };
};




{ deleteVehicle (_x select 0) } foreach _leftLights;
{ deleteVehicle (_x select 0) } foreach _rightLights;




_leftLights = [];
_rightLights = [];

Alles anzeigen

John_Parker

fn_medicSirenLights.sqf:

Code

/*
	File: fn_sirenLights.sqf
	Author: Bryan "Tonic" Boardwine

	Description:
	Lets play a game! Can you guess what it does? I have faith in you, if you can't
	then you have failed me and therefor I lose all faith in humanity.. No pressure.
*/
private["_vehicle"];
_vehicle = [_this,0,ObjNull,[ObjNull]] call BIS_fnc_param;
if(isNull _vehicle) exitWith {}; //Bad entry!
if(!(typeOf _vehicle in ["C_Offroad_01_F","B_MRAP_01_F","C_SUV_01_F","I_Heli_light_03_F","B_Heli_Light_01_F","C_Hatchback_01_sport_F","I_MRAP_03_F","O_MRAP_02_F","O_MRAP_02_hmg_F","B_MRAP_01_hmg_F","I_MRAP_03_hmg_F","C_Van_01_box_F"])) exitWith {}; //Last chance check to prevent something from defying humanity and creating a monster.




_trueorfalse = _vehicle getVariable["lights",FALSE];




if(_trueorfalse) then {
	_vehicle setVariable["lights",FALSE,TRUE];
} else {
	_vehicle setVariable["lights",TRUE,TRUE];
	[[_vehicle,0.22],"life_fnc_medicLights",true,false] call life_fnc_MP;
};

Alles anzeigen

fn_keyhandler.sqf:

Code

#include <macro.h>
/*
	File: fn_keyHandler.sqf
	Author: Bryan "Tonic" Boardwine




	Description:
	Main key handler for event 'keyDown'
*/
private ["_handled","_shift","_alt","_code","_ctrl","_alt","_ctrlKey","_veh","_locked","_interactionKey","_mapKey","_interruptionKeys"];
_ctrl = SEL(_this,0);
_code = SEL(_this,1);
_shift = SEL(_this,2);
_ctrlKey = SEL(_this,3);
_alt = SEL(_this,4);
_speed = speed cursorTarget;
_handled = false;




_interactionKey = if((EQUAL(count (actionKeys "User10"),0))) then {219} else {(actionKeys "User10") select 0};
_mapKey = SEL(actionKeys "ShowMap",0);
//hint str _code;
_interruptionKeys = [17,30,31,32]; //A,S,W,D




//Vault handling...
if((_code in (actionKeys "GetOver") || _code in (actionKeys "salute")) && {(player GVAR ["restrained",false])}) exitWith {
	true;
};




if(life_action_inUse) exitWith {
	if(!life_interrupted && _code in _interruptionKeys) then {life_interrupted = true;};
	_handled;
};




//Hotfix for Interaction key not being able to be bound on some operation systems.
if(!(EQUAL(count (actionKeys "User10"),0)) && {(inputAction "User10" > 0)}) exitWith {
	//Interaction key (default is Left Windows, can be mapped via Controls -> Custom -> User Action 10)
	if(!life_action_inUse) then {
		[] spawn {
			private "_handle";
			_handle = [] spawn life_fnc_actionKeyHandler;
			waitUntil {scriptDone _handle};
			life_action_inUse = false;
		};
	};
	true;
};




switch (_code) do {
	//Space key for Jumping
	case 57: {
		if(isNil "jumpActionTime") then {jumpActionTime = 0;};
		if(_shift && {!(EQUAL(animationState player,"AovrPercMrunSrasWrflDf"))} && {isTouchingGround player} && {EQUAL(stance player,"STAND")} && {speed player > 2} && {!life_is_arrested} && {SEL((velocity player),2) < 2.5} && {time - jumpActionTime > 1.5}) then {
			jumpActionTime = time; //Update the time.
			[player,true] spawn life_fnc_jumpFnc; //Local execution
			[[player,false],"life_fnc_jumpFnc",nil,FALSE] call life_fnc_MP; //Global execution
			_handled = true;
		};
	};




	//Map Key
	case _mapKey: {
		switch (playerSide) do {
			case west: {if(!visibleMap) then {[] spawn life_fnc_copMarkers;}};
			case independent: {if(!visibleMap) then {[] spawn life_fnc_medicMarkers;}};
			case civilian: {if(!visibleMap) then {[] spawn life_fnc_civMarker;}};
		};
	};




	//Holster / recall weapon.
	case 35: {
		if(_shift && !_ctrlKey && !(EQUAL(currentWeapon player,""))) then {
			life_curWep_h = currentWeapon player;
			player action ["SwitchWeapon", player, player, 100];
			player switchCamera cameraView;
		};




		if(!_shift && _ctrlKey && !isNil "life_curWep_h" && {!(EQUAL(life_curWep_h,""))}) then {
			if(life_curWep_h in [RIFLE,LAUNCHER,PISTOL]) then {
				player selectWeapon life_curWep_h;
			};
		};
	};




	//Interaction key (default is Left Windows, can be mapped via Controls -> Custom -> User Action 10)
	case _interactionKey: {
		if(!life_action_inUse) then {
			[] spawn  {
				private "_handle";
				_handle = [] spawn life_fnc_actionKeyHandler;
				waitUntil {scriptDone _handle};
				life_action_inUse = false;
			};
		};
	};




	//F1 = Faded Sound
	case 59:
	{
		[] call life_fnc_fadeSound;
		_handled = true;
	};




	//Restraining or robbing (Shift + R)
	case 19:
	{
		if(_shift) then {_handled = true;};
		if(_shift && playerSide == west && !isNull cursorTarget && cursorTarget isKindOf "Man" && (isPlayer cursorTarget) && (side cursorTarget == civilian) && alive cursorTarget && cursorTarget distance player < 3.5 && !(cursorTarget GVAR "Escorting") && !(cursorTarget GVAR "restrained") && speed cursorTarget < 1) then
		{
			[] call life_fnc_restrainAction;
		};




		//Robbing
		if(_shift && playerSide == civilian && !isNull cursorTarget && cursorTarget isKindOf "Man" && isPlayer cursorTarget && alive cursorTarget && cursorTarget distance player < 4 && speed cursorTarget < 1) then
		{
			if((animationState cursorTarget) != "Incapacitated" && (currentWeapon player == RIFLE OR currentWeapon player == PISTOL) && currentWeapon player != "" && !life_knockout && !(player GVAR["restrained",false]) && !life_istazed && !(player GVAR["surrender",false])) then
			{
				[cursorTarget] spawn life_fnc_knockoutAction;
			};
			_handled = true;
		};
	};




	//Shift + G (surrender)
	case 34:
	{
		if(_shift) then {_handled = true;};




		if (_shift) then
		{
			if (vehicle player == player && !(player GVAR ["restrained", false]) && (animationState player) != "Incapacitated" && !life_istazed) then
			{
				if (player GVAR ["surrender", false]) then
				{
					player SVAR ["surrender", false, true];
				} else
				{
					[] spawn life_fnc_surrender;
				};
			};
		};
	};




	//Num1
	case 79:
	{
	if(_shift) then {_handled = true;};
		if ((_shift) && (vehicle player == player)) then
		{
			cutText [format["Taekwondo"], "PLAIN DOWN"];
			player playMove "AmovPercMstpSnonWnonDnon_exerciseKata";
		};
	};




	//Num2
	case 80:
	{
	if(_shift) then {_handled = true;};
		if ((_shift) && (vehicle player == player)) then
		{
			cutText [format["Kniebeuge"], "PLAIN DOWN"];
			player playMove "AmovPercMstpSnonWnonDnon_exercisekneeBendA";
		};
	};




	//Num3
	case 81:
	{
	if(_shift) then {_handled = true;};
		if ((_shift) && (vehicle player == player)) then
		{
			cutText [format["Hastige Kniebeuge"], "PLAIN DOWN"];
			player playMove "AmovPercMstpSnonWnonDnon_exercisekneeBendB";
		};
	};




	//Num4
	case 75:
	{
	if(_shift) then {_handled = true;};
		if ((_shift) && (vehicle player == player)) then
		{
			cutText [format["Liegestütze"], "PLAIN DOWN"];
			player playMove "AmovPercMstpSnonWnonDnon_exercisePushup";
		};
	};




	case 76:
	{
			if(_shift) then {_handled = true;};
			if((_shift) && (vehicle player == player)) then
	{
			[] spawn {
				player playMove "Acts_AidlPercMstpSlowWrflDnon_pissing";
				[player,"piss"] call life_fnc_globalSound;
				sleep 8;
				_pipi = "Oil_Spill_F" createVehicle (getPos player);
				_pipi setPos (getPos player);
				sleep 120;
				deleteVehicle _pipi;
		};
	};
};










	//T Key (Trunk)
	case 20: {
		if(!_alt && !_ctrlKey && !life_is_processing) then {
			if(vehicle player != player && alive vehicle player) then {
				if((vehicle player) in life_vehicles) then {
					[vehicle player] call life_fnc_openInventory;
				};
			} else {
				private "_list";
				_list = ["landVehicle","Air","Ship","House_F"];
				if(KINDOF_ARRAY(cursorTarget,_list) && {player distance cursorTarget < 7} && {vehicle player == player} && {alive cursorTarget}) then {
					if(cursorTarget in life_vehicles OR {!(cursorTarget GVAR ["locked",true])}) then {
						[cursorTarget] call life_fnc_openInventory;
					};
				};
			};
		};
	};




	case 18:
	{
		if(_shift && playerSide == west  && !(life_siren4_active) && vehicle player != player && ((driver vehicle player) == player)) then
		{
			_veh = vehicle player;
			[[_veh,"takedown_weapon"],"life_fnc_globalSound",true,false] spawn life_fnc_MP;
			[] spawn
			{
				life_siren4_active = true;
				sleep 4.2;
				life_siren4_active = false;
			};
			_handled = true;
		};
	};




	case 46:
	{
		if(_shift && playerSide == west && !(life_siren5_active) && vehicle player != player && ((driver vehicle player) == player)) then
		{
			_veh = vehicle player;
			[[_veh,"follow"],"life_fnc_globalSound",true,false] spawn life_fnc_MP;
			[] spawn
			{
				life_siren5_active = true;
				sleep 4.5;
				life_siren5_active = false;
			};
			_handled = true;
		};
	};




	case 16:
	{
		if(_shift && playerSide == west && !(life_siren2_active) && vehicle player != player && ((driver vehicle player) == player)) then
		{
			_veh = vehicle player;
			[[_veh,"stop_car"],"life_fnc_globalSound",true,false] spawn life_fnc_MP;
			[] spawn
			{
				life_siren2_active = true;
				sleep 3.5;
				life_siren2_active = false;
			};
			_handled = true;
		};
	};




	case 24:
	{
		if (!_shift && !_alt && !_ctrlKey && (playerSide == west) && (vehicle player != player)) then {
			[] call life_fnc_copOpener;
		};
	};




	//NEW ONE
//L Key?
case 38: {
 //If cop run checks for turning lights on.
 if(!isNil {vehicle player getVariable "lights"} && vehicle player != player && _shift) then {
 if (!(vehicle player getVariable "lights")) then {
 [vehicle player, player] spawn life_fnc_emergencyLights;
 } else {
 vehicle player setVariable ["lights", false, true];
 };
 };
 if(!_alt && !_ctrlKey) then { [] call life_fnc_radar; };
};




	case 41: {




		if (!_alt && !_ctrlKey && playerSide == west) then
		{
			[] call life_fnc_radar;
		};
	};




	//Y Player Menu
	case 21: {
		if(!_alt && !_ctrlKey && !dialog && !life_is_processing) then {
			[] call life_fnc_p_openMenu;
		};
	};




	case 33: //F Key = Sirens
    {
        if (!_shift && !_alt && !_ctrlKey) then //F Key = EMS/Cops Sirens
        {
            _veh = vehicle player;
            if(playerSide in [west,independent] && _veh != player && !life_siren_active && ((driver _veh) == player)) then
            {
                [] spawn
                {
                    life_siren_active = true;
                    uiSleep 0.5;
                    life_siren_active = false;
                };
                if(isNil {_veh getVariable "siren"}) then {_veh setVariable["siren",false,true];};
                if((_veh getVariable "siren")) then
                {
                    titleText [localize "STR_MISC_SirensOFF","PLAIN"];
                    _veh setVariable["siren",false,true];
                } else {
                    titleText [localize "STR_MISC_SirensON","PLAIN"];
                    _veh setVariable["siren",true,true];
                    if(playerSide == west) then {
                        [[_veh],"life_fnc_copSiren",nil,true] spawn life_fnc_MP;
                    } else {
                        [[_veh],"life_fnc_medicSiren2",nil,true] spawn life_fnc_MP;
                    };
                };
            };
        };
		if(_shift && playerSide == west && !(life_yelp_active) && vehicle player != player && ((driver vehicle player) == player)) then
		{
			_veh = vehicle player;
			[[_veh,"Yelp"],"life_fnc_globalSound",true,false] spawn life_fnc_MP;
			[] spawn
			{
				life_Yelp_active = true;
				sleep 3.5;
				life_Yelp_active = false;
			};
			_handled = true;
		};
		//medyelp new
		if(_shift && playerSide == independent && !(life_medyelp_active) && vehicle player != player && ((driver vehicle player) == player)) then
		{
			_veh = vehicle player;
			[[_veh,"medyelp"],"life_fnc_globalSound",true,false] spawn life_fnc_MP;
			[] spawn
			{
				life_medyelpelp_active = true;
				sleep 3.5;
				life_medyelp_active = false;
			};
			_handled = true;
		};
	};
		/*
		//Medic siren Shift+F (yelp)
		if(_shift) then
            {
                if(playerSide == independent && vehicle player != player && !life_siren4_active && ((driver vehicle player) == player)) then
                {
                    [] spawn
                    {
                        life_siren4_active = true;
                        sleep 1.2;
                        life_siren4_active = false;
                    };
                    _veh = vehicle player;
                    if(isNil {_veh getVariable "siren4"}) then {_veh setVariable["siren4",false,true];};
                    if((_veh getVariable "siren4")) then
                    {
                        titleText ["Signal aus","PLAIN"];
                        _veh setVariable["siren4",false,true];
                    }
                        else
                    {
                        titleText ["Signal an","PLAIN"];
                        _veh setVariable["siren4",true,true];
                        [[_veh],"life_fnc_medicSiren",nil,true] spawn life_fnc_MP;
                    };
                };
            };
		};
		*/
	//U Key
	case 22:
	{
		if(!_alt && !_ctrlKey) then {
			if(vehicle player == player) then {
				_veh = cursorTarget;
			} else {
				_veh = vehicle player;
			};




			if(_veh isKindOf "House_F" && playerSide == civilian) then {
				if(_veh in life_vehicles && player distance _veh < 8) then {
					_door = [_veh] call life_fnc_nearestDoor;
					if(EQUAL(_door,0)) exitWith {hint "Du bist nicht in der Nähe einer Tür!"};
					_locked = _veh GVAR [format["bis_disabled_Door_%1",_door],0];
					if (EQUAL(_locked,0)) then {
						_veh SVAR[format["bis_disabled_Door_%1",_door],1,true];
						_veh animate [format["door_%1_rot",_door],0];
						hint composeText [ image "icons\lock.paa", "  Tür abgeschlossen" ];
					} else {
						_veh SVAR[format["bis_disabled_Door_%1",_door],0,true];
						_veh animate [format["door_%1_rot",_door],1];
						hint composeText [ image "icons\unlock.paa", "  Tür aufgeschlossen" ];
					};
				};
			} else {
				_locked = locked _veh;




			if(_veh in life_vehicles && player distance _veh < 8) then
			{
				if(_locked == 2) then
				{
					if(local _veh) then
					{
						_veh lock 0;
						_veh animateDoor ["door_back_R",1];
						_veh animateDoor ["door_back_L",1];
        					_veh animateDoor ['door_R',1];
        					_veh animateDoor ['door_L',1];
        					_veh animateDoor ['Door_rear',1];
        					_veh animateDoor ['Door_LM',1];
        					_veh animateDoor ['Door_RM',1];
        					_veh animateDoor ['Door_LF',1];
        					_veh animateDoor ['Door_RF',1];
        					_veh animateDoor ['Door_LB',1];
        					_veh animateDoor ['Door_RB',1];
					}
						else
					{
						[[_veh,0], "life_fnc_lockVehicle",_veh,false] spawn life_fnc_MP;
						_veh animateDoor ["door_back_R",1];
						_veh animateDoor ["door_back_L",1];
        					_veh animateDoor ['door_R',1];
        					_veh animateDoor ['door_L',1];
        					_veh animateDoor ['Door_rear',1];
        					_veh animateDoor ['Door_LM',1];
        					_veh animateDoor ['Door_RM',1];
        					_veh animateDoor ['Door_LF',1];
        					_veh animateDoor ['Door_RF',1];
        					_veh animateDoor ['Door_LB',1];
        					_veh animateDoor ['Door_RB',1];
					};
					hint composeText [ image "icons\unlock.paa", "  Fahrzeug aufgeschlossen" ];
					player say3D "unlock";




				}
					else
				{
					if(local _veh) then
					{
						_veh lock 2;
						_veh animateDoor ["door_back_R",0];
						_veh animateDoor ["door_back_L",0];
        					_veh animateDoor ['door_R',0];
        					_veh animateDoor ['door_L',0];
        					_veh animateDoor ['Door_rear',0];
        					_veh animateDoor ['Door_LM',0];
        					_veh animateDoor ['Door_RM',0];
        					_veh animateDoor ['Door_LF',0];
        					_veh animateDoor ['Door_RF',0];
        					_veh animateDoor ['Door_LB',0];
        					_veh animateDoor ['Door_RB',0];




					}
						else
					{
						[[_veh,2], "life_fnc_lockVehicle",_veh,false] spawn life_fnc_MP;
						_veh animateDoor ["door_back_R",0];
						_veh animateDoor ["door_back_L",0];
        					_veh animateDoor ['door_R',0];
        					_veh animateDoor ['door_L',0];
        					_veh animateDoor ['Door_rear',0];
        					_veh animateDoor ['Door_LM',0];
        					_veh animateDoor ['Door_RM',0];
        					_veh animateDoor ['Door_LF',0];
        					_veh animateDoor ['Door_RF',0];
        					_veh animateDoor ['Door_LB',0];
        					_veh animateDoor ['Door_RB',0];
					};




					hint composeText [ image "icons\lock.paa", "  Fahrzeug abgeschlossen" ];
					player say3D "car_lock";







					};
				};
			};
		};
	};
};




_handled;

Alles anzeigen

Saturin78

Hi, der Abschnitt in deiner keyhandler für das L (Blaulicht) sieht seltsam aus. Sieht nach einem Script aus das hier mal war mit sonder Blaulicht.

Normal sollte das so aussehen.

Spoiler anzeigen

//(Shift + L) Blaulicht normal
case 38: {
//If cop run checks for turning lights on.
if(_shift && playerSide in [west,independent]) then {
if(vehicle player != player && (typeOf vehicle player) in [
"C_Hatchback_01_F",
"C_Heli_light_01_vrana_F",
"C_Hatchback_01_sport_F",
"B_Heli_Light_01_F",
"B_Heli_Transport_01_F",
"I_Heli_light_03_unarmed_F",
"I_MRAP_03_F",
"B_MRAP_01_hmg_F",
"C_Van_01_box_F",
"C_Offroad_01_F",
"B_MRAP_01_F",
"C_SUV_01_F",
"I_Truck_02_box_F",
"B_Truck_01_transport_F"
]) then {
if(!isNil {vehicle player GVAR "lights"}) then {
if(playerSide == west) then {
[vehicle player] call life_fnc_sirenLights;
} else {
[vehicle player] call life_fnc_medicSirenLights;
};
_handled = true;
};
};
};

if(!_alt && !_ctrlKey) then { [] call life_fnc_radar; };
};

Ersetz den Teil mal und teste es bitte.

MfG

Satuirn78

PS. das emergencyLights ist von dem anderen Script mit dem schönen Blaulicht für Offroader. Das gehört zu dem Script:
[Ein Tutorial] Das sagenumwobene Blaulichtscript von der die Rede war...

John_Parker

Zitat von Saturin78

Hi, der Abschnitt in deiner keyhandler für das L (Blaulicht) sieht seltsam aus. Sieht nach einem Script aus das hier mal war mit sonder Blaulicht.

Normal sollte das so aussehen.

Spoiler anzeigen

//(Shift + L) Blaulicht normal
case 38: {
//If cop run checks for turning lights on.
if(_shift && playerSide in [west,independent]) then {
if(vehicle player != player && (typeOf vehicle player) in [
"C_Hatchback_01_F",
"C_Heli_light_01_vrana_F",
"C_Hatchback_01_sport_F",
"B_Heli_Light_01_F",
"B_Heli_Transport_01_F",
"I_Heli_light_03_unarmed_F",
"I_MRAP_03_F",
"B_MRAP_01_hmg_F",
"C_Van_01_box_F",
"C_Offroad_01_F",
"B_MRAP_01_F",
"C_SUV_01_F",
"I_Truck_02_box_F",
"B_Truck_01_transport_F"
]) then {
if(!isNil {vehicle player GVAR "lights"}) then {
if(playerSide == west) then {
[vehicle player] call life_fnc_sirenLights;
} else {
[vehicle player] call life_fnc_medicSirenLights;
};
_handled = true;
};
};
};

if(!_alt && !_ctrlKey) then { [] call life_fnc_radar; };
};

Ersetz den Teil mal und teste es bitte.

MfG

Satuirn78

PS. das emergencyLights ist von dem anderen Script mit dem schönen Blaulicht für Offroader. Das gehört zu dem Script:
[Ein Tutorial] Das sagenumwobene Blaulichtscript von der die Rede war...

Alles anzeigen

Hallo,

danke erstmals für deinen beitrag.
Ich Besitze die anderen Blaulichter in meiner Mission. Also das mit dem Offroader
Deswegen sieht warscheinlich auch meine Keyhandler anders aus, wobei wie gesagt ich benutze die Native-Network Missionsfile.

Saturin78

Ich habe das andere Blaulicht script auch eingebaut.

Habe es aber auf die Taste Shift + B gelegt, weil das Blaulicht nur auf dem Offroader gut rüber kommt finde ich.

Dann ersetz dein Blaulicht mal komplett mit dem, dann kannst testen ob es am keyhandler liegt. Wie gesegt, Shift + L normales Blaulicht und Shift + B das andere.

Spoiler anzeigen

//(Shift + L) Blaulicht normal
case 38: {
//If cop run checks for turning lights on.
if(_shift && playerSide in [west,independent]) then {
if(vehicle player != player && (typeOf vehicle player) in [
"C_Hatchback_01_F",
"C_Heli_light_01_vrana_F",
"C_Hatchback_01_sport_F",
"B_Heli_Light_01_F",
"B_Heli_Transport_01_F",
"I_Heli_light_03_unarmed_F",
"I_MRAP_03_F",
"B_MRAP_01_hmg_F",
"C_Van_01_box_F",
"C_Offroad_01_F",
"B_MRAP_01_F",
"C_SUV_01_F",
"I_Truck_02_box_F",
"B_Truck_01_transport_F"
]) then {
if(!isNil {vehicle player GVAR "lights"}) then {
if(playerSide == west) then {
[vehicle player] call life_fnc_sirenLights;
} else {
[vehicle player] call life_fnc_medicSirenLights;
};
_handled = true;
};
};
};

if(!_alt && !_ctrlKey) then { [] call life_fnc_radar; };
};

//Sonderblaulicht
//(Shift + B) Sonder Blaulicht
case 48: {
//If cop run checks for turning lights on.
if(_shift && playerSide in [west,independent]) then {
if(!isNil {vehicle player GVAR "lights"} && vehicle player != player) then {
if (!(vehicle player GVAR "lights")) then {
[vehicle player, player] spawn life_fnc_emergencyLights;
} else {
vehicle player setVariable ["lights", false, true];
};
};
//if(!_alt && !_ctrlKey) then { [] call life_fnc_radar; };
};
};

John_Parker

Benutzt du 3.1.4.8 Version oder 4.0 ?
Denn ich benutze die 4.0 Version

Saturin78

ich nutze 4.0

Saturin78

Ich hab bei mir halt noch den Zamak, Hemtt und die Helis eingefügt.

Kommentier deins mal aus und dann das von mir rein zum testen.

Wenn es dann nicht geht liegt es schonmal nicht an den Keys.

John_Parker

Ok dann versuche ich das mal mit deinem Code
Ich gebe dann gleich mal bescheid

@ kannst du mir zufällig auch bei dem Heli Shop prob von dem Medics weiterhelfen ?

Saturin78

Brauch ich nähere Infos. Also die config_vehicle.

John_Parker

das ist die config_vehicles.hpp, denn das ist ein eigener Shop erstellt denke ich mal von Nox oder irgend jemand von Native-Network:

P.s musste es als dateianhang machen weil die datei zu groß ist für den code

Saturin78

Das sieht soweit ok aus. wie ist der Aufruf in deiner Init des Shops?

Die Helis aus dem med_air_hs werden wahrscheinlich auf dem Krankenhaus spawnen.

John_Parker

Richtig eigentlich schon.
Aber es werden im Shop keine Helis angezeigt obwohl ich diese eingetragen habe sieht man ja.

Saturin78

kannst du aus deiner mission den shop hier mal posten? Also den Aufruf auf den shop, der in der init des NPC´s?

John_Parker

Code

this enableSimulation false;  this allowDamage false; this addAction["Fahrzeugladen",life_fnc_vehicleShopMenu,["med_shop",independent,"med_car_1","med","Kavala Hosptial"]];  this addAction["Lorenzo's Luftfahrt",life_fnc_vehicleShopMenu,["med_air",independent,"medic_spawn_1","med","Kavala Hosptial"]];  this addAction["Garage",  {   [[getPlayerUID player,playerSide,"Car",player],"TON_fnc_getVehicles",false,false] call life_fnc_MP;   createDialog "Life_impound_menu";   disableSerialization;   ctrlSetText[2802,"Lade Fahrzeuge..."];   life_garage_sp = "med_car_1"; life_garage_type = "Car";  },"",0,false,false,"",'playerSide == independent '];  this addAction["Helicopter Garage",  {   [[getPlayerUID player,playerSide,"Air",player],"TON_fnc_getVehicles",false,false] call life_fnc_MP;   createDialog "Life_impound_menu";   disableSerialization;   ctrlSetText[2802,"Lade Fahrzeuge..."];   life_garage_sp = "medic_spawn_1"; life_garage_type = "Air";  },"",0,false,false,"",'playerSide == independent '];  this addAction["Einparken",life_fnc_storeVehicle,"",0,false,false,"",'!life_garage_store'];