Kannst du mir helfen?

#include "..\..\script_macros.hpp"
/*
    File: fn_playerTags.sqf
    Author: Bryan "Tonic" Boardwine

    Description:
    Adds the tags above other players heads when close and have visible range.
*/
if (!life_settings_tagson) exitWith {};
private ["_ui","_units","_masks"];
#define iconID 78000
#define scale 0.8

if (visibleMap || {!alive player} || {dialog}) exitWith {
    500 cutText["","PLAIN"];
};

_ui = uiNamespace getVariable ["Life_HUD_nameTags",displayNull];
if (isNull _ui) then {
    500 cutRsc["Life_HUD_nameTags","PLAIN"];
    _ui = uiNamespace getVariable ["Life_HUD_nameTags",displayNull];
};

_units = nearestObjects[(visiblePosition player),["Man","Land_Pallet_MilBoxes_F","Land_Sink_F"],50];
_units = _units - [player];

_masks = LIFE_SETTINGS(getArray,"clothing_masks");
{
    private "_text";
    _idc = _ui displayCtrl (iconID + _forEachIndex);
    if (!(lineIntersects [eyePos player, eyePos _x, player, _x]) && alive _x && {!isNil {_x getVariable "realname"}}) then {
        _pos = switch (typeOf _x) do {
            case "Land_Pallet_MilBoxes_F": {[visiblePosition _x select 0, visiblePosition _x select 1, (getPosATL _x select 2) + 1.5]};
            case "Land_Sink_F": {[visiblePosition _x select 0, visiblePosition _x select 1, (getPosATL _x select 2) + 2]};
            default {[visiblePosition _x select 0, visiblePosition _x select 1, ((_x modelToWorld (_x selectionPosition "head")) select 2)+.5]};
        };
        _sPos = worldToScreen _pos;
        _distance = _pos distance player;
        if (!((headgear _x) in _masks || (goggles _x) in _masks || (uniform _x) in _masks)) then {
            if (count _sPos > 1 && {_distance < 15}) then {
                _text = switch (true) do {
                    case (_x in (units group player) && playerSide == civilian): {format ["<t color='#00FF00'>%1</t>",(_x getVariable ["realname",name _x])];};
                    case (!isNil {(_x getVariable "rank")} && side _x == west): {format["<img image='%1' size='1.5'></img> <t size='1.1' color='#0055FF'>%3<br/></t>%2",switch ((_x getVariable "rank")) do {
                        case 1: {"icons\cop\PPR.paa"};
                        case 2: {"icons\cop\PA.paa"};
                        case 3: {"icons\cop\PM.paa"};
                        case 4: {"icons\cop\POM.paa"};
                        case 5: {"icons\cop\PHM.paa"};
                        case 6: {"icons\cop\PKA.paa"};
                        case 7: {"icons\cop\PK.paa"};
                        case 8: {"icons\cop\POK.paa"};
                        case 9: {"icons\cop\PHK.paa"};
                        case 10: {"icons\cop\LPHK.paa"};
                        case 11: {"icons\cop\PR.paa"};
                        case 12: {"icons\cop\PD.paa"};
                        case 13: {"icons\cop\LPD.paa"};
                        case 14: {"icons\map\regularlimnos_CA.paa"};
                        default {""};
                         },
                    _x getVariable ["realname",name _x],switch ((_x getVariable "rank")) do {
                        case 1: {"Polizeipraktikant"};
                        case 2: {"Polizeianwärter"};
                        case 3: {"Polizeimeister"};
                        case 4: {"Polizeiobermeister"};
                        case 5: {"Polizeihauptmeister"};
                        case 6: {"Polizeikommissaranwärter"};
                        case 7: {"Polizeikommissar"};
                        case 8: {"Polizeioberkommissar"};
                        case 9: {"Polizeihauptkommissar"};
                        case 10: {"Leitender Polizeihauptkommissar"};
                        case 11: {"Polizeirat"};
                        case 12: {"Polizeidirektor"};
                        case 13: {"Leitender Polizeidirektor"};
                        case 14: {"Landesverwaltung"};
                        default {"Nicht gelistet"};
                         }]};
                    case (side _x == independent): {format["<img image='icons\map\mediclimnos_CA.paa' size='1.5'></img> <t size='1.1' color='#FF0000'>%2<br/></t>%1",_x getVariable ["realname",name _x],switch ((_x getVariable "medrank")) do {
                        case 1: {"RDIL Praktikant"};
                        case 2: {"Ersthelfer"};
                        case 3: {"Rettungshelfer"};
                        case 4: {"Notfallsanitäter"};
                        case 5: {"Assistenzarzt"};
                        case 6: {"Notarzt"};
                        case 7: {"Oberarzt"};
                        case 8: {"Chefarzt"};
                        default {"Nicht gelistet"};
                         }]};
                    default {
                        if (!isNil {(group _x) getVariable "gang_name"}) then {
                            format ["%1<br/><t size='0.8' color='#B6B6B6'>%2</t>",_x getVariable ["realname",name _x],(group _x) getVariable ["gang_name",""]];
                        } else {
                            if (alive _x) then {
                                _x getVariable ["realname",name _x];
                            } else {
                                if (!isPlayer _x) then {
                                    _x getVariable ["realname","ERROR"];
                                };
                            };
                        };
                    };
                };

                _idc ctrlSetStructuredText parseText _text;
                _idc ctrlSetPosition [_sPos select 0, _sPos select 1, 0.4, 0.65];
                _idc ctrlSetScale scale;
                _idc ctrlSetFade 0;
                _idc ctrlCommit 0;
                _idc ctrlShow true;
            } else {
                _idc ctrlShow false;
            };
        } else {
            _idc ctrlShow false;
        };
    } else {
        _idc ctrlShow false;
    };
} forEach _units;