DR. Schild und Garge Frage

Moin. Ich habe 2 Frage und hoffe mir kann wer weiter helfen

1. Wie bekomme ich DR Schild umgeschrieben das er ACE zurücksetzt? Habe davon schon mal was gelesen aber ich habe nicht verstanden wie ich den Kram nun einfügen muss. (Link)

2. Mir Kamm eine Idee nur haperst es an der Umsetzung. Wie bekomme ich die Garage in eine 3d Ansicht? Wie beim Auto Laden.

Ich verwende die Altis Life 5.0.0 Hier aus dem Forum. Wenn weiteres Benötigt wird einfach anfragen.

Zu 1 am okay ich such mal weiter.

Zu 2 Ich versuch heute Abend mal was. Ich weiß aber absolut nicht ob ich das hin bekomme. Aber wer nicht wagt der nicht verliert.

Ich teste das heute Abend und wenn ich es Hinbekommen. Dann melde ich mich. Ich werde auch Veränderungen dann mitteilen.

Zitat von moeck

Nagut, das Ganze dürfte doch simpler sein als ich dachte. Allerdings übernehme ich mal keine Garantie da ich es nicht getestet habe

Ich habe baue das jetzt einfach mal ein, der Dialog muss dann aber noch angepasst werden, da er sich aktuell mittig befindet und wahrscheinlich das Ganze einwenig überdeckt

So dann hier mal der Ansatz

1. impound.hpp

C: \dialog\impound.hpp

class Life_impound_menu {
    idd = 2800;
    name="life_vehicle_shop";
    movingEnable = 0;
    enableSimulation = 1;
    onLoad = "ctrlShow [2330,false];";
    onUnLoad = "[] call life_fnc_vehicleShopEnd3DPreview";

    class controlsBackground {
        class Life_RscTitleBackground: Life_RscText    {
            colorBackground[] = {"(profilenamespace getvariable ['GUI_BCG_RGB_R',0.3843])", "(profilenamespace getvariable ['GUI_BCG_RGB_G',0.7019])", "(profilenamespace getvariable ['GUI_BCG_RGB_B',0.8862])", "(profilenamespace getvariable ['GUI_BCG_RGB_A',0.7])"};
            idc = -1;
            x = 0.1;
            y = 0.2;
            w = 0.8;
            h = (1 / 25);
        };

        class MainBackground: Life_RscText {
            colorBackground[] = {0,0,0,0.7};
            idc = -1;
            x = 0.1;
            y = 0.2 + (11 / 250);
            w = 0.8;
            h = 0.7 - (22 / 250);
        };

        class Title: Life_RscTitle {
            idc = 2801;
            text = "$STR_GUI_Garage";
            x = 0.1;
            y = 0.2;
            w = 0.8;
            h = (1 / 25);
        };

        class VehicleTitleBox: Life_RscText {
            idc = -1;
            text = "$STR_GUI_YourVeh";
            colorBackground[] = {"(profilenamespace getvariable ['GUI_BCG_RGB_R',0.3843])", "(profilenamespace getvariable ['GUI_BCG_RGB_G',0.7019])", "(profilenamespace getvariable ['GUI_BCG_RGB_B',0.8862])", "(profilenamespace getvariable ['GUI_BCG_RGB_A',0.7])"};
            x = 0.11;
            y = 0.26;
            w = 0.3;
            h = (1 / 25);
        };

        class VehicleInfoHeader: Life_RscText {
            idc = 2830;
            text = "$STR_GUI_VehInfo";
            colorBackground[] = {"(profilenamespace getvariable ['GUI_BCG_RGB_R',0.3843])", "(profilenamespace getvariable ['GUI_BCG_RGB_G',0.7019])", "(profilenamespace getvariable ['GUI_BCG_RGB_B',0.8862])", "(profilenamespace getvariable ['GUI_BCG_RGB_A',0.7])"};
            x = 0.42;
            y = 0.26;
            w = 0.46;
            h = (1 / 25);
        };

        class CloseBtn: Life_RscButtonMenu {
            idc = -1;
            text = "$STR_Global_Close";
            onButtonClick = "closeDialog 0;";
            x = -0.06 + (6.25 / 40) + (1 / 250 / (safezoneW / safezoneH));
            y = 0.9 - (1 / 25);
            w = (6.25 / 40);
            h = (1 / 25);
        };

        class RetrieveCar: Life_RscButtonMenu {
            idc = -1;
            text = "$STR_Global_Retrieve";
            onButtonClick = "[] call life_fnc_unimpound;";
            x = 0.1 + (6.25 / 40) + (1 / 250 / (safezoneW / safezoneH));
            y = 0.9 - (1 / 25);
            w = (6.25 / 40);
            h = (1 / 25);
        };

        class SellCar: Life_RscButtonMenu {
            idc = -1;
            text = "$STR_Global_Sell";
            onButtonClick = "[] call life_fnc_sellGarage; closeDialog 0;";
            x = 0.26 + (6.25 / 40) + (1 / 250 / (safezoneW / safezoneH));
            y = 0.9 - (1 / 25);
            w = (6.25 / 40);
            h = (1 / 25);
        };
    };

    class controls {
        class VehicleList: Life_RscListBox {
            idc = 2802;
            text = "";
            sizeEx = 0.04;
            colorBackground[] = {0.1,0.1,0.1,0.9};
            onLBSelChanged = "_this call life_fnc_garageLBChange;";
            x = 0.11;
            y = 0.302;
            w = 0.303;
            h = 0.49;
        };

        class vehicleInfomationList: Life_RscStructuredText {
            idc = 2803;
            text = "";
            sizeEx = 0.035;
            x = 0.41;
            y = 0.3;
            w = 0.5;
            h = 0.5;
        };

        class MainBackgroundHider: Life_RscText {
            colorBackground[] = {0,0,0,1};
            idc = 2810;
            x = 0.1;
            y = 0.2 + (11 / 250);
            w = 0.8;
            h = 0.7 - (22 / 250);
        };

        class MainHideText: Life_RscText {
            idc = 2811;
            text = "$STR_ANOTF_QueryGarage";
            sizeEx = 0.06;
            x = 0.24;
            y = 0.5;
            w = 0.6;
            h = (1 / 15);
        };
    };
};

Alles anzeigen

2. fn_impoundMenu.sqf

C: \dialog\function\impoundMenu.hpp

#include "..\..\script_macros.hpp"
/*
    File: fn_impoundMenu.sqf
    Author: Bryan "Tonic" Boardwine

    Description:
    Not actually a impound menu, may act as confusion to some but that is what I wanted.
    The purpose of this menu is it is now called a 'Garage' where vehicles are stored (persistent ones).
*/
private ["_vehicles","_control"];
disableSerialization;
_vehicles = param [0,[],[[]]];

ctrlShow[2803,false];
ctrlShow[2830,false];
waitUntil {!isNull (findDisplay 2800)};

if (count _vehicles isEqualTo 0) exitWith {
    ctrlSetText[2811,localize "STR_Garage_NoVehicles"];
};

_control = CONTROL(2800,2802);
lbClear _control;

{
    _vehicleInfo = [(_x select 2)] call life_fnc_fetchVehInfo;
    _control lbAdd (_vehicleInfo select 3);
    _tmp = [(_x select 2),(_x select 8)];
    _tmp = str(_tmp);
    _control lbSetData [(lbSize _control)-1,_tmp];
    _control lbSetPicture [(lbSize _control)-1,(_vehicleInfo select 2)];
    _control lbSetValue [(lbSize _control)-1,(_x select 0)];
} forEach _vehicles;
if (LIFE_SETTINGS(getNumber,"vehicleShop_3D") isEqualTo 1) then {
  [] call life_fnc_vehicleShopInit3DPreview;
};
ctrlShow[2810,false];
ctrlShow[2811,false];

Alles anzeigen

3. fn_garageLBChange.sqf

C: \dialog\function\garageLBChange.sqf

#include "..\..\script_macros.hpp"
/*
    File: fn_garageLBChange.sqf
    Author: Bryan "Tonic" Boardwine

    Description:
    Can't be bothered to answer it.. Already deleted it by accident..
*/
disableSerialization;
private ["_control","_index","_className","_classNameLife","_dataArr","_vehicleColor","_vehicleInfo","_trunkSpace","_sellPrice","_retrievePrice","_sellMultiplier","_price","_storageFee","_purchasePrice"];
_control = _this select 0;
_index = _this select 1;

//Fetch some information.
_dataArr = CONTROL_DATAI(_control,_index);
_dataArr = call compile format ["%1",_dataArr];
_className = (_dataArr select 0);
_classNameLife = _className;

if (!isClass (missionConfigFile >> "LifeCfgVehicles" >> _classNameLife)) then {
    _classNameLife = "Default"; //Use Default class if it doesn't exist
    diag_log format ["%1: LifeCfgVehicles class doesn't exist",_className];
};

_vehicleColor = ((M_CONFIG(getArray,"LifeCfgVehicles",_classNameLife,"textures") select (_dataArr select 1)) select 0);
if (isNil "_vehicleColor") then {_vehicleColor = "Default";};

_vehicleInfo = [_className] call life_fnc_fetchVehInfo;
_trunkSpace = [_className] call life_fnc_vehicleWeightCfg;

_price = M_CONFIG(getNumber,"LifeCfgVehicles",_classNameLife,"price");
_storageFee = LIFE_SETTINGS(getNumber,"vehicle_storage_fee_multiplier");

switch (playerSide) do {
    case civilian: {
        _purchasePrice = _price * LIFE_SETTINGS(getNumber,"vehicle_purchase_multiplier_CIVILIAN");
        _sellMultiplier = LIFE_SETTINGS(getNumber,"vehicle_sell_multiplier_CIVILIAN");
    };
    case west: {
        _purchasePrice = _price * LIFE_SETTINGS(getNumber,"vehicle_purchase_multiplier_COP");
        _sellMultiplier = LIFE_SETTINGS(getNumber,"vehicle_sell_multiplier_COP");
    };
    case independent: {
        _purchasePrice = _price * LIFE_SETTINGS(getNumber,"vehicle_purchase_multiplier_MEDIC");
        _sellMultiplier = LIFE_SETTINGS(getNumber,"vehicle_sell_multiplier_MEDIC");
    };
    case east: {
        _purchasePrice = _price * LIFE_SETTINGS(getNumber,"vehicle_purchase_multiplier_OPFOR");
        _sellMultiplier = LIFE_SETTINGS(getNumber,"vehicle_sell_multiplier_OPFOR");
    };
};
_retrievePrice = _purchasePrice * _storageFee;
_sellPrice = _purchasePrice * _sellMultiplier;

if (!(_sellPrice isEqualType 0) || _sellPrice < 1) then {_sellPrice = 500;};
if (!(_retrievePrice isEqualType 0) || _retrievePrice < 1) then {_retrievePrice = 500;};
[_className] call life_fnc_vehicleShop3DPreview;
(CONTROL(2800,2803)) ctrlSetStructuredText parseText format [
    (localize "STR_Shop_Veh_UI_RetrievalP")+ " <t color='#8cff9b'>$%1</t><br/>
    " +(localize "STR_Shop_Veh_UI_SellP")+ " <t color='#8cff9b'>$%2</t><br/>
    " +(localize "STR_Shop_Veh_UI_Color")+ " %8<br/>
    " +(localize "STR_Shop_Veh_UI_MaxSpeed")+ " %3 km/h<br/>
    " +(localize "STR_Shop_Veh_UI_HPower")+ " %4<br/>
    " +(localize "STR_Shop_Veh_UI_PSeats")+ " %5<br/>
    " +(localize "STR_Shop_Veh_UI_Trunk")+ " %6<br/>
    " +(localize "STR_Shop_Veh_UI_Fuel")+ " %7
    ",
[_retrievePrice] call life_fnc_numberText,
[_sellPrice] call life_fnc_numberText,
(_vehicleInfo select 8),
(_vehicleInfo select 11),
(_vehicleInfo select 10),
if (_trunkSpace isEqualTo -1) then {"None"} else {_trunkSpace},
(_vehicleInfo select 12),
_vehicleColor
];

ctrlShow [2803,true];
ctrlShow [2830,true];

Alles anzeigen

Also mit ein wenig Glück sollte das schon reichen und die Garage hat eine 3D Ansicht

Gruß,

moeck

Alles anzeigen

Ich habe nach langem mal wieder weiter machen können. Ich habe nun die Garage soweit eingebaut und es Funktioniert auch soweit das ich das Fahrzeug einmal Ausparken konnte. Danach gehst nicht mehr

Zitat von moeck

achso man könnte natürlich die Einstellungen aus dem Vehicle Shop übernehmen wenn man sich keine Arbeit machen möchte

Da ich hier gerade nix zum testen habe könnte der Dialog komisch aussehen

C: \dialog\impound.hpp

class Life_impound_menu {
    idd = 2800;
    name="life_vehicle_shop";
    movingEnable = 0;
    enableSimulation = 1;
    onLoad = "ctrlShow [2330,false];";

    class controlsBackground {
        class Life_RscTitleBackground: Life_RscText    {
            colorBackground[] = {"(profilenamespace getvariable ['GUI_BCG_RGB_R',0.3843])", "(profilenamespace getvariable ['GUI_BCG_RGB_G',0.7019])", "(profilenamespace getvariable ['GUI_BCG_RGB_B',0.8862])", "(profilenamespace getvariable ['GUI_BCG_RGB_A',0.7])"};
            idc = -1;
            x = 0.809375 * safezoneW + safezoneX;
            y = 0.06 * safezoneH + safezoneY;
            w = 0.190781 * safezoneW;
            h = 0.341 * safezoneH;
        };

        class MainBackground: Life_RscText {
            colorBackground[] = {0,0,0,0.7};
            idc = -1;
            x = 0.0204687 * safezoneW + safezoneX;
            y = 0.06 * safezoneH + safezoneY;
            w = 0.149531 * safezoneW;
            h = 0.638 * safezoneH;
        };

        class Title: Life_RscTitle {
            idc = 2801;
            text = "$STR_GUI_Garage";
            x = 0.0204687 * safezoneW + safezoneX;
            y = 0.027 * safezoneH + safezoneY;
            w = 0.144375 * safezoneW;
            h = 0.033 * safezoneH;
        };

        class VehicleTitleBox: Life_RscText {
            idc = -1;
            text = "$STR_GUI_YourVeh";
            colorBackground[] = {"(profilenamespace getvariable ['GUI_BCG_RGB_R',0.3843])", "(profilenamespace getvariable ['GUI_BCG_RGB_G',0.7019])", "(profilenamespace getvariable ['GUI_BCG_RGB_B',0.8862])", "(profilenamespace getvariable ['GUI_BCG_RGB_A',0.7])"};
            x = 0.0204687 * safezoneW + safezoneX;
            y = 0.06 * safezoneH + safezoneY;
            w = 0.149531 * safezoneW;
            h = 0.033 * safezoneH;
        };

        class VehicleInfoHeader: Life_RscText {
            idc = 2830;
            text = "$STR_GUI_VehInfo";
            colorBackground[] = {"(profilenamespace getvariable ['GUI_BCG_RGB_R',0.3843])", "(profilenamespace getvariable ['GUI_BCG_RGB_G',0.7019])", "(profilenamespace getvariable ['GUI_BCG_RGB_B',0.8862])", "(profilenamespace getvariable ['GUI_BCG_RGB_A',0.7])"};
           x = 0.809375 * safezoneW + safezoneX;
            y = 0.058 * safezoneH + safezoneY;
            w = 0.190781 * safezoneW;
            h = 0.022 * safezoneH;
        };

        class CloseBtn: Life_RscButtonMenu {
            idc = -1;
            text = "$STR_Global_Close";
            onButtonClick = "closeDialog 0;";
             x = 0.0204687 * safezoneW + safezoneX;
            y = 0.669387 * safezoneH + safezoneY;
            w = 0.0721724 * safezoneW;
            h = 0.0219957 * safezoneH;
        };

        class RetrieveCar: Life_RscButtonMenu {
            idc = -1;
            text = "$STR_Global_Retrieve";
            onButtonClick = "[] call life_fnc_unimpound;";
            x = 0.0964687 * safezoneW + safezoneX;
            y = 0.636393 * safezoneH + safezoneY;
            w = 0.0721724 * safezoneW;
            h = 0.0219957 * safezoneH;
        };

        class SellCar: Life_RscButtonMenu {
            idc = -1;
            text = "$STR_Global_Sell";
            onButtonClick = "[] call life_fnc_sellGarage; closeDialog 0;";
            x = 0.0204687 * safezoneW + safezoneX;
            y = 0.636393 * safezoneH + safezoneY;
            w = 0.0721724 * safezoneW;
            h = 0.0219957 * safezoneH;
        };
    };

    class controls {
        class VehicleList: Life_RscListBox {
            idc = 2802;
            text = "";
            sizeEx = 0.04;
            colorBackground[] = {0.1,0.1,0.1,0.9};
            onLBSelChanged = "_this call life_fnc_garageLBChange;";
             x = 0.023487 * safezoneW + safezoneX;
            y = 0.095 * safezoneH + safezoneY;
            w = 0.144375 * safezoneW;
            h = 0.50 * safezoneH;
        };

        class vehicleInfomationList: Life_RscStructuredText {
            idc = 2803;
            text = "";
            sizeEx = 0.035;
            x = 0.819688 * safezoneW + safezoneX;
            y = 0.104 * safezoneH + safezoneY;
            w = 0.175313 * safezoneW;
            h = 0.275 * safezoneH;
        };

        class MainBackgroundHider: Life_RscText {
            colorBackground[] = {0,0,0,1};
            idc = 2810;
            x = 0.1;
            y = 0.2 + (11 / 250);
            w = 0.8;
            h = 0.7 - (22 / 250);
        };

        class MainHideText: Life_RscText {
            idc = 2811;
            text = "$STR_ANOTF_QueryGarage";
            sizeEx = 0.06;
            x = 0.24;
            y = 0.5;
            w = 0.6;
            h = (1 / 15);
        };
    };
};

Alles anzeigen

Außerdem musste ich den Dialog etwas umschreiben.

class Life_impound_menu {
   idd = 2800;
   name = "Life_impound_menu";
   movingenable = 0;
   enablesimulation = 1;
   onload = "ctrlShow [2330,false];";
   onunload = "[] call life_fnc_vehicleShopEnd3DPreview";
   class controlsBackground
   {
       class Life_RscTitleBackground : Life_RscText
       {
           colorbackground[] = {"(profilenamespace getvariable ['GUI_BCG_RGB_R',0.3843])", "(profilenamespace getvariable ['GUI_BCG_RGB_G',0.7019])", "(profilenamespace getvariable ['GUI_BCG_RGB_B',0.8862])", "(profilenamespace getvariable ['GUI_BCG_RGB_A',0.7])"};
           idc = -1;
           x = 0.809375 * safezoneW + safezoneX;
           y = 0.06 * safezoneH + safezoneY;
           w = 0.190781 * safezoneW;
           h = 0.341 * safezoneH;
       };
       class MainBackground : Life_RscText
       {
           colorbackground[] = {0,0,0,0.7};
           idc = -1;
           x = 0.0204687 * safezoneW + safezoneX;
           y = 0.06 * safezoneH + safezoneY;
           w = 0.149531 * safezoneW;
           h = 0.638 * safezoneH;
       };
       class Title : Life_RscTitle
       {
           idc = 2801;
           text = "$STR_GUI_Garage";
           x = 0.0204687 * safezoneW + safezoneX;
           y = 0.027 * safezoneH + safezoneY;
           w = 0.144375 * safezoneW;
           h = 0.033 * safezoneH;
       };
       class VehicleTitleBox : Life_RscText
       {
           idc = -1;
           text = "$STR_GUI_YourVeh";
           colorbackground[] = {"(profilenamespace getvariable ['GUI_BCG_RGB_R',0.3843])", "(profilenamespace getvariable ['GUI_BCG_RGB_G',0.7019])", "(profilenamespace getvariable ['GUI_BCG_RGB_B',0.8862])", "(profilenamespace getvariable ['GUI_BCG_RGB_A',0.7])"};
           x = 0.0204687 * safezoneW + safezoneX;
           y = 0.06 * safezoneH + safezoneY;
           w = 0.149531 * safezoneW;
           h = 0.033 * safezoneH;
       };
       class VehicleInfoHeader : Life_RscText
       {
           idc = 2830;
           text = "$STR_GUI_VehInfo";
           colorbackground[] = {"(profilenamespace getvariable ['GUI_BCG_RGB_R',0.3843])", "(profilenamespace getvariable ['GUI_BCG_RGB_G',0.7019])", "(profilenamespace getvariable ['GUI_BCG_RGB_B',0.8862])", "(profilenamespace getvariable ['GUI_BCG_RGB_A',0.7])"};
           x = 0.809375 * safezoneW + safezoneX;
           y = 0.058 * safezoneH + safezoneY;
           w = 0.190781 * safezoneW;
           h = 0.022 * safezoneH;
       };
       class CloseBtn : Life_RscButtonMenu
       {
           text = "$STR_Global_Close";
           onbuttonclick = "closeDialog 0;";
           x = 0.0204687 * safezoneW + safezoneX;
           y = 0.669387 * safezoneH + safezoneY;
           w = 0.0721724 * safezoneW;
           h = 0.0219957 * safezoneH;
       };
       class RetrieveCar : Life_RscButtonMenu
       {
           text = "$STR_Global_Retrieve";
           onbuttonclick = "[] call life_fnc_unimpound;";
           x = 0.0964687 * safezoneW + safezoneX;
           y = 0.636393 * safezoneH + safezoneY;
           w = 0.0721724 * safezoneW;
           h = 0.0219957 * safezoneH;
       };
       class SellCar : Life_RscButtonMenu
       {
           text = "$STR_Global_Sell";
           onbuttonclick = "[] call life_fnc_sellGarage; closeDialog 0;";
           x = 0.0204687 * safezoneW + safezoneX;
           y = 0.636393 * safezoneH + safezoneY;
           w = 0.0721724 * safezoneW;
           h = 0.0219957 * safezoneH;
       };
   };
   class controls
   {
       class VehicleList : Life_RscListBox
       {
           idc = 2802;
           text = "";
           sizeex = 0.04;
           colorbackground[] = {0.1,0.1,0.1,0.9};
           onlbselchanged = "_this call life_fnc_garageLBChange;";
           x = 0.023487 * safezoneW + safezoneX;
           y = 0.095 * safezoneH + safezoneY;
           w = 0.144375 * safezoneW;
           h = 0.50 * safezoneH;
       };
       class vehicleInfomationList : Life_RscStructuredText
       {
           idc = 2803;
           sizeex = 0.035;
           x = 0.819688 * safezoneW + safezoneX;
           y = 0.104 * safezoneH + safezoneY;
           w = 0.175313 * safezoneW;
           h = 0.275 * safezoneH;
       };
       class MainBackgroundHider : Life_RscText
       {
           colorbackground[] = {0,0,0,1};
           idc = 2810;
           x = 0.1;
           y = 0.2 + (11 / 250);
           w = 0.8;
           h = 0.7 - (22 / 250);
       };
       class MainHideText : Life_RscText
       {
           idc = 2811;
           text = "$STR_ANOTF_QueryGarage";
           sizeex = 0.06;
           x = 0.24;
           y = 0.5;
           w = 0.6;
           h = (1 / 15);
       };
   };
};

Meine RPT Log hänge ich mal an

MFG

taker

Zitat von moeck

Moin,

Code

Error in expression <,((_parts select 0) select _i)],_damage select _i];
};
};





if ((_vInfo selec>
  Error position: <select _i];
};
};





if ((_vInfo selec>
  Error Generic error in expression
File \life_server\Functions\Systems\fn_spawnVehicle.sqf [TON_fnc_spawnVehicle], line 275

Alles anzeigen

da ist dein Garagenfehler. Da passt was im life_server (fn_spawnVehicle) nicht.

Gruß,

moeck

Da habe ich nix geändert

#include "\life_server\script_macros.hpp"
/*
 File: fn_spawnVehicle.sqf
 Author: Bryan "Tonic" Boardwine




 Description:
 Sends the query request to the database, if an array is returned then it creates
 the vehicle if it's not in use or dead.
*/
private ["_vid","_sp","_pid","_query","_sql","_vehicle","_nearVehicles","_name","_side","_tickTime","_dir","_servIndex","_damage","_wasIllegal","_location","_thread"];
_vid = [_this,0,-1,[0]] call BIS_fnc_param;
_pid = [_this,1,"",[""]] call BIS_fnc_param;
_sp = [_this,2,[],[[],""]] call BIS_fnc_param;
_unit = [_this,3,objNull,[objNull]] call BIS_fnc_param;
_price = [_this,4,0,[0]] call BIS_fnc_param;
_dir = [_this,5,0,[0]] call BIS_fnc_param;
_spawntext = _this select 6;
_unit_return = _unit;
_name = name _unit;
_side = side _unit;
_unit = owner _unit;




if (_vid isEqualTo -1 || _pid isEqualTo "") exitWith {};
if (_vid in serv_sv_use) exitWith {};
serv_sv_use pushBack _vid;
_servIndex = serv_sv_use find _vid;




_query = format ["SELECT id, side, classname, type, pid, alive, active, plate, color, inventory, gear, fuel, damage, blacklist, impound FROM vehicles WHERE id='%1' AND pid='%2'",_vid,_pid];




_tickTime = diag_tickTime;
_queryResult = [_query,2] call DB_fnc_asyncCall;




if (EXTDB_SETTING(getNumber,"DebugMode") isEqualTo 1) then {
 diag_log "------------- Client Query Request -------------";
 diag_log format ["QUERY: %1",_query];
 diag_log format ["Time to complete: %1 (in seconds)",(diag_tickTime - _tickTime)];
 diag_log format ["Result: %1",_queryResult];
 diag_log "------------------------------------------------";
};




if (_queryResult isEqualType "") exitWith {};




_vInfo = _queryResult;
if (isNil "_vInfo") exitWith {serv_sv_use deleteAt _servIndex;};
if (count _vInfo isEqualTo 0) exitWith {serv_sv_use deleteAt _servIndex;};




if ((_vInfo select 5) isEqualTo 0) exitWith {
 serv_sv_use deleteAt _servIndex;
 [1,"STR_Garage_SQLError_Destroyed",true,[_vInfo select 2]] remoteExecCall ["life_fnc_broadcast",_unit];
};




if ((_vInfo select 6) isEqualTo 1) exitWith {
 serv_sv_use deleteAt _servIndex;
 [1,"STR_Garage_SQLError_Active",true,[_vInfo select 2]] remoteExecCall ["life_fnc_broadcast",_unit];
};




if (!(_sp isEqualType "")) then {
 _nearVehicles = nearestObjects[_sp,["Car","Air","Ship"],10];
} else {
 _nearVehicles = [];
};




if (count _nearVehicles > 0) exitWith {
 serv_sv_use deleteAt _servIndex;
 [_price,_unit_return] remoteExecCall ["life_fnc_garageRefund",_unit];
 [1,"STR_Garage_SpawnPointError",true] remoteExecCall ["life_fnc_broadcast",_unit];
};




_query = format ["UPDATE vehicles SET active='1', impound='0', damage='""[]""' WHERE pid='%1' AND id='%2'",_pid,_vid];




_trunk = [(_vInfo select 9)] call DB_fnc_mresToArray;
_gear = [(_vInfo select 10)] call DB_fnc_mresToArray;
_damage = [(_vInfo select 12)] call DB_fnc_mresToArray;
_wasIllegal = (_vInfo select 13);
_wasIllegal = if (_wasIllegal isEqualTo 1) then { true } else { false };




[_query,1] call DB_fnc_asyncCall;
if (_sp isEqualType "") then {
 _vehicle = createVehicle[(_vInfo select 2),[0,0,999],[],0,"NONE"];
 waitUntil {!isNil "_vehicle" && {!isNull _vehicle}};
 _vehicle allowDamage false;
 _hs = nearestObjects[getMarkerPos _sp,["Land_Hospital_side2_F"],50] select 0;
 _vehicle setPosATL (_hs modelToWorld [-0.4,-4,12.65]);
 uiSleep 0.6;
} else {
 _vehicle = createVehicle [(_vInfo select 2),_sp,[],0,"NONE"];
 waitUntil {!isNil "_vehicle" && {!isNull _vehicle}};
 _vehicle allowDamage false;
 _vehicle setPos _sp;
 _vehicle setVectorUp (surfaceNormal _sp);
 _vehicle setDir _dir;
};
_vehicle allowDamage true;
//Send keys over the network.
[_vehicle] remoteExecCall ["life_fnc_addVehicle2Chain",_unit];
[_pid,_side,_vehicle,1] call TON_fnc_keyManagement;
_vehicle lock 2;
//Reskin the vehicle
[_vehicle,(_vInfo select 8)] remoteExecCall ["life_fnc_colorVehicle",_unit];
_vehicle setVariable ["vehicle_info_owners",[[_pid,_name]],true];
_vehicle setVariable ["dbInfo",[(_vInfo select 4),(_vInfo select 7)],true];
_vehicle disableTIEquipment true; //No Thermals.. They're cheap but addictive.
[_vehicle] call life_fnc_clearVehicleAmmo;




// Avoid problems if u keep changing which stuff to save!
if (LIFE_SETTINGS(getNumber,"save_vehicle_virtualItems") isEqualTo 1) then {
 _vehicle setVariable ["Trunk",_trunk,true];
 if (_wasIllegal) then {
 if (_sp isEqualType "") then {
 _location= (nearestLocations [getPos _sp,["NameCityCapital","NameCity","NameVillage"],1000]) select 0;
 } else {
 _location= (nearestLocations [_sp,["NameCityCapital","NameCity","NameVillage"],1000]) select 0;
 };
 _location = text _location;
 [1,"STR_NOTF_BlackListedVehicle",true,[_location,_name]] remoteExecCall ["life_fnc_broadcast",west];




 _query = format ["UPDATE vehicles SET blacklist='0' WHERE id='%1' AND pid='%2'",_vid,_pid];
 _thread = [_query,1] call DB_fnc_asyncCall;
 };
 }else{
 _vehicle setVariable ["Trunk",[[],0],true];
};




if (LIFE_SETTINGS(getNumber,"save_vehicle_fuel") isEqualTo 1) then {
 _vehicle setFuel (_vInfo select 11);
 }else{
 _vehicle setFuel 1;
};




if (count _gear > 0 && (LIFE_SETTINGS(getNumber,"save_vehicle_inventory") isEqualTo 1)) then {
 _items = _gear select 0;
 _mags = _gear select 1;
 _weapons = _gear select 2;
 _backpacks = _gear select 3;




 for "_i" from 0 to ((count (_items select 0)) - 1) do {
 _vehicle addItemCargoGlobal [((_items select 0) select _i), ((_items select 1) select _i)];
 };
 for "_i" from 0 to ((count (_mags select 0)) - 1) do {
 _vehicle addMagazineCargoGlobal [((_mags select 0) select _i), ((_mags select 1) select _i)];
 };
 for "_i" from 0 to ((count (_weapons select 0)) - 1) do {
 _vehicle addWeaponCargoGlobal [((_weapons select 0) select _i), ((_weapons select 1) select _i)];
 };
 for "_i" from 0 to ((count (_backpacks select 0)) - 1) do {
 _vehicle addBackpackCargoGlobal [((_backpacks select 0) select _i), ((_backpacks select 1) select _i)];
 };
};




if (count _damage > 0 && (LIFE_SETTINGS(getNumber,"save_vehicle_damage") isEqualTo 1)) then {
 _parts = getAllHitPointsDamage _vehicle;




 for "_i" from 0 to ((count _damage) - 1) do {
 _vehicle setHitPointDamage [format ["%1",((_parts select 0) select _i)],_damage select _i];
 };
};




//Sets of animations
if ((_vInfo select 1) isEqualTo "civ" && (_vInfo select 2) isEqualTo "B_Heli_Light_01_F" && !((_vInfo select 8) isEqualTo 13)) then {
 [_vehicle,"civ_littlebird",true] remoteExecCall ["life_fnc_vehicleAnimate",_unit];
};




if ((_vInfo select 1) isEqualTo "cop" && ((_vInfo select 2)) in ["C_Offroad_01_F","B_MRAP_01_F","C_SUV_01_F","C_Hatchback_01_sport_F","B_Heli_Light_01_F","B_Heli_Transport_01_F"]) then {
 [_vehicle,"cop_offroad",true] remoteExecCall ["life_fnc_vehicleAnimate",_unit];
};




if ((_vInfo select 1) isEqualTo "med" && (_vInfo select 2) isEqualTo "C_Offroad_01_F") then {
 [_vehicle,"med_offroad",true] remoteExecCall ["life_fnc_vehicleAnimate",_unit];
};




[1,_spawntext] remoteExecCall ["life_fnc_broadcast",_unit];
serv_sv_use deleteAt _servIndex;

Weiß keiner eine Lösung bzw Ansatz. Habe versucht das selbst zu lösen aber ehrlich gesagt weiß ich nicht wo er da ein Problem hat. Zeile 275 gibst in der Datei nicht. und den Code wo mit er nicht klar kommt ist für die hitpoints bzw auch dafür da wenn das Fahrzeug zerstört wurden ist. Wenn ich das wieder raus nehme funktioniert alles wieder einwandfrei.

MFG

taker

Zitat von Julian

Du includest die script macro

#include "\life_server\script_macros.hpp"

Die datei musst du öffnen und von der zeilen zahl abziehen heisst 247-die anzahl wie viele zeilen die script Macros hat sind meistens 61 das heisst du rechnes bei deinem fehler

musst du 275-61 =214 da muss der fehler liegen....

Du hast die datei aber ausseinander gepflückt

Code

#include "\life_server\script_macros.hpp"
/*
    File: fn_spawnVehicle.sqf
    Author: Bryan "Tonic" Boardwine

    Description:
    Sends the query request to the database, if an array is returned then it creates
    the vehicle if it's not in use or dead.
*/
params [
    ["_vid", -1, [0]],
    ["_pid", "", [""]],
    ["_sp", [], [[],""]],
    ["_unit", objNull, [objNull]],
    ["_price", 0, [0]],
    ["_dir", 0, [0]],
    "_spawntext"
];

private _unit_return = _unit;
private _name = name _unit;
private _side = side _unit;
_unit = owner _unit;

if (_vid isEqualTo -1 || {_pid isEqualTo ""}) exitWith {};
if (_vid in serv_sv_use) exitWith {};
serv_sv_use pushBack _vid;

private _servIndex = serv_sv_use find _vid;

private _query = format ["SELECT id, side, classname, type, pid, alive, active, plate, color, inventory, gear, fuel, damage, blacklist FROM vehicles WHERE id='%1' AND pid='%2'",_vid,_pid];

private _tickTime = diag_tickTime;
private _queryResult = [_query,2] call DB_fnc_asyncCall;

if (EXTDB_SETTING(getNumber,"DebugMode") isEqualTo 1) then {
    diag_log "------------- Client Query Request -------------";
    diag_log format ["QUERY: %1",_query];
    diag_log format ["Time to complete: %1 (in seconds)",(diag_tickTime - _tickTime)];
    diag_log format ["Result: %1",_queryResult];
    diag_log "------------------------------------------------";
};

if (_queryResult isEqualType "") exitWith {};

private _vInfo = _queryResult;
if (isNil "_vInfo") exitWith {serv_sv_use deleteAt _servIndex;};
if (count _vInfo isEqualTo 0) exitWith {serv_sv_use deleteAt _servIndex;};

if ((_vInfo select 5) isEqualTo 0) exitWith {
    serv_sv_use deleteAt _servIndex;
    [1,"STR_Garage_SQLError_Destroyed",true,[_vInfo select 2]] remoteExecCall ["life_fnc_broadcast",_unit];
};

if ((_vInfo select 6) isEqualTo 1) exitWith {
    serv_sv_use deleteAt _servIndex;
    [1,"STR_Garage_SQLError_Active",true,[_vInfo select 2]] remoteExecCall ["life_fnc_broadcast",_unit];
};

private "_nearVehicles";
if !(_sp isEqualType "") then {
    _nearVehicles = nearestObjects[_sp,["Car","Air","Ship"],10];
} else {
    _nearVehicles = [];
};

if (count _nearVehicles > 0) exitWith {
    serv_sv_use deleteAt _servIndex;
    [_price,_unit_return] remoteExecCall ["life_fnc_garageRefund",_unit];
    [1,"STR_Garage_SpawnPointError",true] remoteExecCall ["life_fnc_broadcast",_unit];
};

_query = format ["UPDATE vehicles SET active='1', damage='""[]""' WHERE pid='%1' AND id='%2'",_pid,_vid];

private _trunk = [(_vInfo select 9)] call DB_fnc_mresToArray;
private _gear = [(_vInfo select 10)] call DB_fnc_mresToArray;
private _damage = [call compile (_vInfo select 12)] call DB_fnc_mresToArray;
private _wasIllegal = _vInfo select 13;
_wasIllegal = if (_wasIllegal isEqualTo 1) then { true } else { false };

[_query,1] call DB_fnc_asyncCall;

private "_vehicle";
if (_sp isEqualType "") then {
    _vehicle = createVehicle[(_vInfo select 2),[0,0,999],[],0,"NONE"];
    waitUntil {!isNil "_vehicle" && {!isNull _vehicle}};
    _vehicle allowDamage false;
    _hs = nearestObjects[getMarkerPos _sp,["Land_Hospital_side2_F"],50] select 0;
    _vehicle setPosATL (_hs modelToWorld [-0.4,-4,12.65]);
    uiSleep 0.6;
} else {
    _vehicle = createVehicle [(_vInfo select 2),_sp,[],0,"NONE"];
    waitUntil {!isNil "_vehicle" && {!isNull _vehicle}};
    _vehicle allowDamage false;
    _vehicle setPos _sp;
    _vehicle setVectorUp (surfaceNormal _sp);
    _vehicle setDir _dir;
};
_vehicle allowDamage true;
//Send keys over the network.
[_vehicle] remoteExecCall ["life_fnc_addVehicle2Chain",_unit];
[_pid,_side,_vehicle,1] call TON_fnc_keyManagement;
_vehicle lock 2;
//Reskin the vehicle
[_vehicle,(_vInfo select 8)] remoteExecCall ["life_fnc_colorVehicle",_unit];
_vehicle setVariable ["vehicle_info_owners",[[_pid,_name]],true];
_vehicle setVariable ["dbInfo",[(_vInfo select 4),(_vInfo select 7)],true];
_vehicle disableTIEquipment true; //No Thermals.. They're cheap but addictive.
[_vehicle] call life_fnc_clearVehicleAmmo;

if (LIFE_SETTINGS(getNumber,"save_vehicle_virtualItems") isEqualTo 1) then {

    _vehicle setVariable ["Trunk",_trunk,true];
    
    if (_wasIllegal) then {
        private _refPoint = if (_sp isEqualType "") then {getMarkerPos _sp;} else {_sp;};
        
        private _distance = 100000;
        private "_location";

        {
            private _tempLocation = nearestLocation [_refPoint, _x];
            private _tempDistance = _refPoint distance _tempLocation;
    
            if (_tempDistance < _distance) then {
                _location = _tempLocation;
                _distance = _tempDistance;
            };
            false
    
        } count ["NameCityCapital", "NameCity", "NameVillage"];
 
        _location = text _location;
        [1,"STR_NOTF_BlackListedVehicle",true,[_location,_name]] remoteExecCall ["life_fnc_broadcast",west];

        _query = format ["UPDATE vehicles SET blacklist='0' WHERE id='%1' AND pid='%2'",_vid,_pid];
        [_query,1] call DB_fnc_asyncCall;
    };
} else {
    _vehicle setVariable ["Trunk",[[],0],true];
};

if (LIFE_SETTINGS(getNumber,"save_vehicle_fuel") isEqualTo 1) then {
    _vehicle setFuel (_vInfo select 11);
    }else{
    _vehicle setFuel 1;
};

if (count _gear > 0 && (LIFE_SETTINGS(getNumber,"save_vehicle_inventory") isEqualTo 1)) then {
    _items = _gear select 0;
    _mags = _gear select 1;
    _weapons = _gear select 2;
    _backpacks = _gear select 3;

    for "_i" from 0 to ((count (_items select 0)) - 1) do {
        _vehicle addItemCargoGlobal [((_items select 0) select _i), ((_items select 1) select _i)];
    };
    for "_i" from 0 to ((count (_mags select 0)) - 1) do {
        _vehicle addMagazineCargoGlobal [((_mags select 0) select _i), ((_mags select 1) select _i)];
    };
    for "_i" from 0 to ((count (_weapons select 0)) - 1) do {
        _vehicle addWeaponCargoGlobal [((_weapons select 0) select _i), ((_weapons select 1) select _i)];
    };
    for "_i" from 0 to ((count (_backpacks select 0)) - 1) do {
        _vehicle addBackpackCargoGlobal [((_backpacks select 0) select _i), ((_backpacks select 1) select _i)];
    };
};

if (count _damage > 0 && (LIFE_SETTINGS(getNumber,"save_vehicle_damage") isEqualTo 1)) then {
    _parts = getAllHitPointsDamage _vehicle;

    for "_i" from 0 to ((count _damage) - 1) do {
        _vehicle setHitPointDamage [format ["%1",((_parts select 0) select _i)],_damage select _i];
    };
};

//Sets of animations
if ((_vInfo select 1) isEqualTo "civ" && (_vInfo select 2) isEqualTo "B_Heli_Light_01_F" && !((_vInfo select 8) isEqualTo 13)) then {
    [_vehicle,"civ_littlebird",true] remoteExecCall ["life_fnc_vehicleAnimate",_unit];
};

if ((_vInfo select 1) isEqualTo "cop" && ((_vInfo select 2)) in ["C_Offroad_01_F","B_MRAP_01_F","C_SUV_01_F","C_Hatchback_01_sport_F","B_Heli_Light_01_F","B_Heli_Transport_01_F"]) then {
    [_vehicle,"cop_offroad",true] remoteExecCall ["life_fnc_vehicleAnimate",_unit];
};

if ((_vInfo select 1) isEqualTo "med" && (_vInfo select 2) isEqualTo "C_Offroad_01_F") then {
    [_vehicle,"med_offroad",true] remoteExecCall ["life_fnc_vehicleAnimate",_unit];
};

[1,_spawntext] remoteExecCall ["life_fnc_broadcast",_unit];
serv_sv_use deleteAt _servIndex;

Alles anzeigen

So sieht die normale aus teste die mal

und nicht vergessen zur PBO zu machen

Alles anzeigen

Dnake für die Erklärung mit den Zeilen.

Es hat nun alles geklappt mit deiner Datei. Danke!