ACE 3 Reifen über Z Inventar Kaufbar und nutzbar machen?

Cetrux

Guten Abend Zusammen,

ich möchte gerne den Ersatzreifen aus ACE3 für das ZInventar kaufbar und Nutzbar machen.

Könnte mir bitte jemand weiter helfen?

br1zey

Dazu würde ich ein ZItem erstellen womit du bei Benutzung ein Script aufruft und den Reifen Spawnst

Cetrux

Im ZInventar hab ich es bereits eingefügt, aber wie kann ich dafür sorgen das der Reifen Spawn?

Niggelchamp

Moin, bin leider gerade nur am Handy weshalb ich es nur grob beschreiben kann aber es gibt eine Datei namens useItem oder so wo du schreiben kannst was bei dem Benutzen von XY passieren soll."Spawnen" kannst du das ganze dann mit classname createVehicle Position
MfG Niggelchamp

Cetrux

Also bei mir sieht das jetzt so aus, aber leider geht es nicht und die leute können nichts mehr essen und trinken.

Code: Config_vItems.hpp

class ACE_RepairWheel {
        variable = "ACE_RepairWheel";
        displayName = "Ersatzreifen";
        weight = 5;
        buyPrice = 200;
        sellPrice = 10;
        illegal = false;
        edible = -1;
        icon = "";
    };

Das Ist das V Item, was leider nur im Shop mit Preis angezeigt wird ohne Namen.

Code

#include "..\..\script_macros.hpp"
/*
    File: fn_useItem.sqf
    Author: Bryan "Tonic" Boardwine




    Description:
    Main function for item effects and functionality through the player menu.
*/
private "_item";
disableSerialization;
if ((lbCurSel 2005) isEqualTo -1) exitWith {hint localize "STR_ISTR_SelectItemFirst";};
_item = CONTROL_DATA(2005);




switch (true) do {
    case (_item in ["waterBottle","coffee","redgull"]): {
        if ([false,_item,1] call life_fnc_handleInv) then {
            life_thirst = 100;
            if (LIFE_SETTINGS(getNumber,"enable_fatigue") isEqualTo 1) then {player setFatigue 0;};
            if (_item isEqualTo "redgull" && {LIFE_SETTINGS(getNumber,"enable_fatigue") isEqualTo 1}) then {
                [] spawn {
                    life_redgull_effect = time;
                    titleText[localize "STR_ISTR_RedGullEffect","PLAIN"];
                    player enableFatigue false;
                    waitUntil {!alive player || ((time - life_redgull_effect) > (3 * 60))};
                    player enableFatigue true;
                };
            };
        };
    };




    case (_item isEqualTo "boltcutter"): {
        [cursorObject] spawn life_fnc_boltcutter;
        closeDialog 0;
    };
    	case (EQUAL(_item,"ACE_RepairWheel")) : {
		if (([false, _item, 1] call life_fnc_handleInv)) then {
            _wheel = "ACE_Wheel" createVehicle (position player);
            [player, _wheel] call ace_dragging_fnc_carryObject;
			closeDialog 0;
		};
	};




    case (_item isEqualTo "blastingcharge"): {
        player reveal fed_bank;
        (group player) reveal fed_bank;
        [cursorObject] spawn life_fnc_blastingCharge;
        closeDialog 0;
    };




    case (_item isEqualTo "defusekit"): {
        [cursorObject] spawn life_fnc_defuseKit;
        closeDialog 0;
    };




    case (_item isEqualTo "storagesmall"): {
        [false] call life_fnc_storageBox;
    };




    case (_item isEqualTo "storagebig"): {
        [true] call life_fnc_storageBox;
    };




    case (_item isEqualTo "spikeStrip"): {
        if (!isNull life_spikestrip) exitWith {hint localize "STR_ISTR_SpikesDeployment"; closeDialog 0};
        if ([false,_item,1] call life_fnc_handleInv) then {
            [] spawn life_fnc_spikeStrip;
            closeDialog 0;
        };
    };




    case (_item isEqualTo "fuelFull"): {
        if (vehicle player != player) exitWith {hint localize "STR_ISTR_RefuelInVehicle"};
        [] spawn life_fnc_jerryRefuel;
        closeDialog 0;
    };




    case (_item isEqualTo "fuelEmpty"): {
        [] spawn life_fnc_jerryCanRefuel;
        closeDialog 0;
    };




    case (_item isEqualTo "lockpick"): {
        [] spawn life_fnc_lockpick;
        closeDialog 0;
    };




    case (_item in ["apple","rabbit","salema","ornate","mackerel","tuna","mullet","catshark","turtle_soup","hen","rooster","sheep","goat","donuts","tbacon","peach"]): {
        if (!(M_CONFIG(getNumber,"VirtualItems",_item,"edible") isEqualTo -1)) then {
            if ([false,_item,1] call life_fnc_handleInv) then {
                _val = M_CONFIG(getNumber,"VirtualItems",_item,"edible");
                _sum = life_hunger + _val;
                switch (true) do {
                    case (_val < 0 && _sum < 1): {life_hunger = 5;}; //This adds the ability to set the entry edible to a negative value and decrease the hunger without death
                    case (_sum > 100): {life_hunger = 100;};
                    default {life_hunger = _sum;};
                };
            };
        };
    };




    default {
        hint localize "STR_ISTR_NotUsable";
    };
};




[] call life_fnc_p_updateMenu;
[] call life_fnc_hudUpdate;

Alles anzeigen

Joa so sieht des bei mir aus geht aber leider nicht und Fehler Meldungen in den Logs etc. gibts leider auch nicht.

blackfisch

Zitat von Cetrux

EQUAL(_item,"ACE_RepairWheel")

das Macro gibt es nicht mehr in der 4.4r3 (und es ist unnötig.)
-> umschreiben zu _item isEqualTo "ACE_RepairWheel"

und da müsste ein Fehler im Client Log stehen, glaub mir :p
sollte so dann hoffentlich klappen

Cetrux

Danke für die Hilfe.

Leider besteht weiterhin das Problem.

Code

case (_item isEqualTo "ACE_RepairWheel"): {
        if (([false, _item, 1] call life_fnc_handleInv)) then {
        _wheel = "ACE_Wheel" createVehicle (position player);
        [player, _wheel] call ace_dragging_fnc_carryObject;
        closeDialog 0;
    };

Die Logs stehe im Anhang.

blackfisch

Clientlog bitte

Cetrux

Ok habe ich hier im Anhang.

blackfisch

Logs sind soweit sauber... hm

Cetrux

Ok hm. Wie gesagt wenn ich das in der useItem einfüge geht auch kein Essen und Trinken mehr.

Cetrux

Ohman bin ich a depp.

Hab den Fehler gefunden.

hatte Ja das hier drin stehen:

case (_item isEqualTo "ACE_RepairWheel"): {
if (([false, _item, 1] call life_fnc_handleInv)) then {
_wheel = "ACE_Wheel" createVehicle (position player);
[player, _wheel] call ace_dragging_fnc_carryObject;
closeDialog 0;
};

Also 2 Klammern auf und eine zu.

jetz sieht es so aus:

case (_item isEqualTo "ACE_RepairWheel"): {
if (([false, _item, 1] call life_fnc_handleInv)) then {
_wheel = "ACE_Wheel" createVehicle (position player);
[player, _wheel] call ace_dragging_fnc_carryObject;
closeDialog 0;
};
};

und siehe da es geht.

Trozdem Danke ud Super Hilfe

Benutzer online in diesem Thema