[Tutorial] Wanted-Menu Dialog

uuunix

Stringtable hin oder her die Abfrage von 0.1 Sekunden macht das kein Unterschied Schieb den String direkt darein und exec den Auf alle Player Überprüfe vorher ob in deiner Broadcast auch ein parseText hast sonst klappt das nicht

Hier

Code

#include "..\..\script_macros.hpp"
/*
 File: fn_wantedAddP.sqf
 Author:
 Description:
*/
if !(playerSide isEqualTo west) exitWith {hint localize "STR_Cop_wantedList_notCop";};
if ((lbCurSel 2406) isEqualTo -1) exitWith {hint localize "STR_Cop_wantedList_noPlayerSelected";};
if ((lbCurSel 2407) isEqualTo -1) exitWith {hint localize "STR_Cop_wantedList_noCrimeSelected";};
  private _unit = lbData [2406,lbCurSel 2406];
  _unit = call compile format ["%1",_unit];
  private _amount = lbData [2407,lbCurSel 2407];
  if (isNil "_unit") exitWith {};
  if (isNull _unit) exitWith {};
  
    [[3],format ["<t size='1.65' color='#00CD00'>UIPD-Fahndungsliste</t><br/><br/><t size='1.1' align='center'>=<br/>Eine Person wurde zur<br/>Fahndung ausgeschrieben<br/>=</t><br/><br/><br/><t size='0.95' align='left' color='#79CdCd'>Person:</t><t size='1.05' align='right'><br/>%1</t><br/><br/><t size='0.95' align='left' color='#79CDCD'>Ausgeschrieben von:</t><t size='1.05' align='right'><br/>%2</t>",_unit getVariable["realname",name _unit],profileName],false] remoteExecCall ["life_fnc_broadcast",RCLIENT];
  if (life_HC_isActive) then {
    [getPlayerUID _unit,_unit getVariable ["realname",name _unit],_amount] remoteExecCall ["HC_fnc_wantedAdd",HC_Life];
  } else {
    [getPlayerUID _unit,_unit getVariable ["realname",name _unit],_amount] remoteExecCall ["life_fnc_wantedAdd",RSERV];
  };

Alles anzeigen

Braucht ihr nur eure WantedAdd zu ersetzten ...

Ist ungetestet sollte aber klappen

Alles anzeigen

So bei mir verbaut, klappt einwandfrei.

Code: fn_wantedaddp.sqf

#include "..\..\script_macros.hpp"
/*
    File: fn_wantedAddP.sqf
    Author:

*/

if !(playerSide isEqualTo west) exitWith { [(localize "STR_Cop_wantedList_notCop"),"true","fast"] call life_fnc_notification_system; };
if ((lbCurSel 2406) isEqualTo -1) exitWith { [(localize "STR_Cop_wantedList_noPlayerSelected"),"true","fast"] call life_fnc_notification_system; };
if ((lbCurSel 2407) isEqualTo -1) exitWith { [(localize "STR_Cop_wantedList_noCrimeSelected"),"true","fast"] call life_fnc_notification_system; };
private _unit = lbData [2406,lbCurSel 2406];
_unit = call compile format["%1",_unit];
private _amount = lbData [2407,lbCurSel 2407];
if (isNil "_unit") exitWith {};
if (isNull _unit) exitWith {};

[[3],format [localize "STR_Wanted_AddP",_unit getVariable["realname",name _unit],profileName],false] remoteExecCall ["life_fnc_broadcast",RCLIENT];

if (life_HC_isActive) then {
    [getPlayerUID _unit,_unit getVariable ["realname",name _unit],_amount] remoteExecCall ["HC_fnc_wantedAdd",HC_Life];
} else {
    [getPlayerUID _unit,_unit getVariable ["realname",name _unit],_amount] remoteExecCall ["life_fnc_wantedAdd",RSERV];
};

Alles anzeigen

MauGi_LP

Klappt das menu jetzt so oder immer noch fehler?

Rene Lerchberg

Zitat von MauGi_LP

Klappt das menu jetzt so oder immer noch fehler?

Geht 1 barn frei?

MauGi_LP

Zitat von Rene Lerchberg

Geht 1 barn frei?

J hatte mich schon einfach dazu gezwungen es selbst zu testen Trotzdem danke wir haben aktuell nur noch das Problem das der Hint nicht richtig formatiert ist aber das bekommen wir schon selber hin hoffe ich

Rene Lerchberg

Zitat von MauGi_LP

J hatte mich schon einfach dazu gezwungen es selbst zu testen Trotzdem danke wir haben aktuell nur noch das Problem das der Hint nicht richtig formatiert ist aber das bekommen wir schon selber hin hoffe ich

Alles klar ansosten meld dich einfach dann wird dir geholfen

Mr. Chris

Hallo wir haben das Problem, dass bei uns keine Nachricht für die Zivilisten kommt. Stringtable ist korrekt. Wenn wir die Nachricht in der fn_wantedAddP.sqf in die alte Nachricht ändern kommt zumindest ein Hint, welcher aber nur den Quellcode aus der Stringtable anzeigt. Logs sind alle negativ und zeigen keine Auffälligkeiten. Bitte um Hilfe.

RanjidTatu

Hi zusammen,

Kann man hier auch Manuelle Wanteds einfügen? Wenn ja wie?

Grüße,

Ranjid

MauGi_LP

Zitat von RanjidTatu

Hi zusammen,
Kann man hier auch Manuelle Wanteds einfügen? Wenn ja wie?
Grüße,
Ranjid

Was meinst du mit manuelle Wanteds?
Ob du eigene Straftaten einfügen kannst, ja das kannst du in dem du in der Config_Master mal vorbei schaust.
Oder willst du wissen ob man als Polizist einen Spieler manuell fanden lassen kann? Das geht ebenfalls

MauGi_LP

Da wir das System aktuell auch wieder nutzen dachte ich es ist ganz cool wenn wir hier rein posten wie wir das Problem mit "Spieler bekommen keine Hint nachricht bekommen" gelöst haben.
Als erstes:
Wir nutzen die fn_broadcast.sqf von [TUTORIAL][ALTIS LIFE 3.1.4.8/4.0+] ZIVILSCHUTZSIRENE FÜR POLIZEI ob es mit der Original fn_broadcast.sqf aus dem Framework auch geht weiß ich nicht.

Code: fn_broadcast.sqf

/*
    File: fn_broadcast.sqf
    Author: Bryan "Tonic" Boardwine




    Description:
    Broadcast system used in the life mission for multi-notification purposes.
*/
private ["_type","_message"];
_type = [_this,0,0,[[],0]] call BIS_fnc_param;
_message = [_this,1,"",[""]] call BIS_fnc_param;
_localize = [_this,2,false,[false]] call BIS_fnc_param;
_parse = [_this,3,false,[false]] call BIS_fnc_param;




if (_message isEqualTo "") exitWith {};




if (_localize) exitWith {
    _arr = _this select 3;
    _msg = switch (count _arr) do {
        case 0: {localize _message;};
        case 1: {format [localize _message,_arr select 0];};
        case 2: {format [localize _message,_arr select 0, _arr select 1];};
        case 3: {format [localize _message,_arr select 0, _arr select 1, _arr select 2];};
        case 4: {format [localize _message,_arr select 0, _arr select 1, _arr select 2, _arr select 3];};
    };




    if (_type isEqualType []) then {
        for "_i" from 0 to (count _type)-1 do {
            switch (_type select _i) do {
                case 0: {systemChat _msg;};
                case 1: {hint _msg;};
                case 2: {titleText[_msg,"PLAIN"];};
            };
        };
    } else {
        switch (_type) do {
            case 0: {systemChat _msg;};
            case 1: {hint _msg;};
            case 2: {titleText[_msg,"PLAIN"];};
        };
    };
};
if (_parse) then {
    if (_type isEqualType []) then {
        for "_i" from 0 to (count _type)-1 do {
            switch (_type select _i) do {
                case 0: {systemChat _message};
                case 1: {hint parseText format ["%1", _message]};
                case 2: {titleText[parseText format ["%1",_message],"PLAIN"];};
            };
        };
    } else {
        switch (_type) do {
            case 0: {systemChat _message};
            case 1: {hint parseText format ["%1", _message]};
            case 2: {titleText[parseText format ["%1",_message],"PLAIN"];};
        };
    };
} else {
    if (_type isEqualType []) then {
        for "_i" from 0 to (count _type)-1 do {
            switch (_type select _i) do {
                case 0: {systemChat _message};
                case 1: {hint format ["%1", _message]};
                case 2: {titleText[format ["%1",_message],"PLAIN"];};
            };
        };
    } else {
        switch (_type) do {
            case 0: {systemChat _message};
            case 1: {hint format ["%1", _message]};
            case 2: {titleText[format ["%1",_message],"PLAIN"];};
        };
    };
};

Alles anzeigen

So jetzt zu wie unsere fn_wantedAddP.sqf aussieht:
Bei Schritt zwei soll man die Zeile

Code

[1,"STR_Wanted_AddP",true,[_unit getVariable ["realname",name _unit],_amount,getPlayerUID _unit]] remoteExecCall ["life_fnc_broadcast",RCLIENT];

durch

Code

[[3],format [localize "STR_Wanted_AddP",_unit getVariable["realname",name _unit],profileName],false] remoteExecCall ["life_fnc_broadcast",RCLIENT];

ersetzen.
Wir haben die Zeile durch folgendes ersetzt:

Code

[[1],format ["<t size='1.65' color='#00CD00'>UIPD-Fahndungsliste</t><br/><br/><t size='1.1' align='center'>=<br/>Eine Person wurde zur<br/>Fahndung ausgeschrieben<br/>=</t><br/><br/><br/><t size='0.95' align='left' color='#79CdCd'>Person:</t><t size='1.05' align='right'><br/>%1</t><br/><br/><t size='0.95' align='left' color='#79CDCD'>Ausgeschrieben von:</t><t size='1.05' align='right'><br/>%2</t>",_unit getVariable["realname",name _unit],profileName],false,true] remoteExecCall ["life_fnc_broadcast",RCLIENT];

[Tutorial] Wanted-Menu Dialog

Ähnliche Themen

[TUTORIAL] EMP Script mit dem Heli Autos stoppen (Cops)

[Tutorial] Spawnintro mit Logo und Musik

[Tutorial] Risk's Hilfe Menü

Cop Fahrzeuge Beschlagnahmen und Abfragen funktioniert nicht.

Benutzer online in diesem Thema